;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Xlib Window Example for x86_64 Linux ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

format ELF64 executable 3
entry main

;;;;;;;;;;;;;;;;;;;;
;; import section ;;
;;;;;;;;;;;;;;;;;;;;

include 'import64.inc'

interpreter '/lib64/ld-linux-x86-64.so.2'

needed 'libX11.so.6'

import XOpenDisplay,\
       XDefaultRootWindow,\
       XCreateSimpleWindow,\
       XSelectInput,\
       XStoreName,\
       XMapWindow,\
       XInternAtom,\
       XSetWMProtocols,\
       XNextEvent,\
       XDestroyWindow,\
       XCloseDisplay

;;;;;;;;;;;;;;;;;;;;;
;; equates section ;;
;;;;;;;;;;;;;;;;;;;;;

; Xlib Constants
KeyPressMask  = 1
KeyPress      = 2
ClientMessage = 33

;;;;;;;;;;;;;;;;;;
;; code section ;;
;;;;;;;;;;;;;;;;;;

segment readable executable

main:
    ; note: rsp should be already aligned for 0-stack-arg calls

    ; Open connection to X server
    xor rdi, rdi                ; char *display_name (NULL)
    call [XOpenDisplay]
    test rax, rax
    jz exit_main
    mov [display_handle], rax

    ; Get default root window
    mov rdi, rax                ; Display *display
    call [XDefaultRootWindow]
    mov [root_handle], rax

    ; -------------------------------------------------------------------------

    ; XCreateSimpleWindow (9 parameters)
    ; First 6 parameters go in registers.
    ; Last 3 parameters go on stack. (right to left)

    ; Load registers for params 1-6
    mov rdi, [display_handle]       ; 1st param: Display *display
    mov rsi, [root_handle]          ; 2nd param: Window parent
    mov rdx, 0                      ; 3rd param: int x
    mov rcx, 0                      ; 4th param: int y
    mov r8, 320                     ; 5th param: unsigned int width
    mov r9, 240                     ; 6th param: unsigned int height

    ; Reserve 32 bytes (4 slots) to keep 16-byte alignment
    ; (3 parameters * 8 bytes = 24 bytes, rounded up to 32)
    sub rsp, 32
    mov qword [rsp+16], 0x00FFFFFF  ; 9th param: unsigned long background (color)
    mov qword [rsp+8],  0x00000000  ; 8th param: unsigned long border (color)
    mov qword [rsp],    2           ; 7th param: unsigned int border_width

    ; Create the window
    call [XCreateSimpleWindow]
    mov [window_handle], rax
    add rsp, 32                     ; Restore stack alignment

    ; -------------------------------------------------------------------------

    ; Select input types
    mov rdi, [display_handle]       ; Display *display
    mov rsi, [window_handle]        ; Window w
    mov rdx, KeyPressMask           ; long event_mask
    call [XSelectInput]

    ; Set window name
    mov rdi, [display_handle]       ; Display *display
    mov rsi, [window_handle]        ; Window w
    mov rdx, window_name_str        ; char *window_name
    call [XStoreName]

    ; Map window to screen
    mov rdi, [display_handle]       ; Display *display
    mov rsi, [window_handle]        ; Window w
    call [XMapWindow]

    ; Call Close Button Handler Sub-function 
    call register_wm_close

    ; Enter the event message loop
event_loop:
    mov rdi, [display_handle]       ; Display *display
    mov rsi, event_buffer           ; XEvent *event_return
    call [XNextEvent]

    mov eax, dword [event_buffer]     
    cmp eax, KeyPress           
    je event_loop_end           

;   TODO: handle other generic events here...

    cmp eax, ClientMessage
    jne event_loop

    mov rax, qword [event_buffer + 56]  ; data.l[0]
    cmp rax, [wm_delete_window]
    je event_loop_end           

;   TODO: handle other ClientMessage events here...

    jmp event_loop

event_loop_end:

    mov qword [exit_code], 0        ; exit status (success)

;exit_cleanup:

    ; Destroy Window instance
    mov rdi, [display_handle]       ; Display *display
    mov rsi, [window_handle]        ; Window w
    call [XDestroyWindow]

    ; Close display connection
    mov rdi, [display_handle]       ; Display *display
    call [XCloseDisplay]

exit_main:

    mov rdi, [exit_code]            ; exit status
    mov rax, 60                     ; exit syscall
    syscall

; =============================================================================

register_wm_close:
    sub rsp, 8                  

    ; Create 'WM_PROTOCOLS' Atom
    mov rdi, [display_handle]       ; Display *display
    mov rsi, wm_protocols_str       ; char *atom_name
    xor rdx, rdx                    ; Bool only_if_exists
    call [XInternAtom]
    mov [wm_protocols], rax

    ; Create 'WM_DELETE_WINDOW' Atom
    mov rdi, [display_handle]       ; Display *display
    mov rsi, wm_delete_window_str   ; char *atom_name
    xor rdx, rdx                    ; Bool only_if_exists
    call [XInternAtom]
    mov [wm_delete_window], rax

    ; Register protocols with window manager
    mov rdi, [display_handle]       ; Display *display
    mov rsi, [window_handle]        ; Window w
    lea rdx, [wm_delete_window]     ; Atom *protocols
    mov rcx, 1                      ; int count
    call [XSetWMProtocols]

    add rsp, 8
    ret

; =============================================================================

;;;;;;;;;;;;;;;;;;
;; data section ;;
;;;;;;;;;;;;;;;;;;

segment readable writeable

align 8
exit_code       dq 1    ; assume failure
display_handle  dq 0
root_handle     dq 0
window_handle   dq 0           

; Explicitly align atoms to 8-byte (64-bit) boundaries
align 8
wm_protocols     dq 0
wm_delete_window dq 0

wm_protocols_str     db 'WM_PROTOCOLS', 0
wm_delete_window_str db 'WM_DELETE_WINDOW', 0
window_name_str      db 'Hello Xlib Linux World!', 0

align 8
event_buffer rb 192
    

You should move to wayland.

You should move to wayland. Xwayland is there only for legacy and it does create problems: it seems it is adding too much latency to some fast games.

If I were you...

Seeking for the minimal footprint possible, ...

Nah Wayland is a joke who can't get some basic things right in the name of "security".

Core wayland is brutally lean, and give the least amount of information to clients.

sylware wrote:

Core wayland is brutally lean, and give the least amount of information to clients.

That's exactly the problem, yes.

Let me put it another way: A hello world program is also brutally lean, which is exactly the problem with it, it's not useful for anything.

Furs wrote:

sylware wrote:

Core wayland is brutally lean, and give the least amount of information to clients.

That's exactly the problem, yes.

Let me put it another way: A hello world program is also brutally lean, which is exactly the problem with it, it's not useful for anything.

???

sylware wrote:

Furs wrote:

sylware wrote:

Core wayland is brutally lean, and give the least amount of information to clients.

That's exactly the problem, yes.

Let me put it another way: A hello world program is also brutally lean, which is exactly the problem with it, it's not useful for anything.

???

I don't know what wasn't clear? Wayland doesn't even give position information to clients last time I checked, you can't restore your window to a saved position etc.

Just because you want to isolate and sandbox every app from another because you're paranoid doesn't mean it's good for the rest of us who'd like our apps to, you know, have more control.