[fasmg] Lucas Prime Test

Index > Macroinstructions > [fasmg] Lucas Prime Test

Goto page Previous 1, 2

Author

Thread

bitRAKE

Joined: 21 Jul 2003
Posts: 2808
Location: dank orb

bitRAKE

Code:

; is F a factor of 2^N-1
macro MFactorQ N*,F*
        local B,T,D
        D = 1 + bsr F
        B = 1
        T = 1
        while B < N & T
                if (B+D) <= N
                        T = ((T+1) shl D)-1
                        B = B + D
                        T = T mod F
                else
                        T = T + T + 1
                        B = B + 1
                        if T >= F
                                T = T mod F
                        end if
                end if
        end while
        repeat 1,t:T,b:B,f:F
                if T = 0
                        display `f,' divides 2^',`b,'-1.',13,10
                else
                        display '2^',`b,'-1 mod ',`f,' = ',`t,13,10
                end if
        end repeat
end macro

MFactorQ 1001664179, 1878753956886303627167 ; 2 min
MFactorQ 3930621659, 6134708376727152865752497 ; 10 min

_________________
¯\(°_o)/¯ unlicense.org

17 Feb 2019, 17:57

bitRAKE

Joined: 21 Jul 2003
Posts: 2808
Location: dank orb

bitRAKE

Is there an a way to terminate the assembly process without producing an error? I don't want an output file, but presently am using "err 'No Output File'".

Code:

test-file.fasmg [66]:
        err 'No Output File'
Custom error: No Output File.
The terminal process terminated with exit code: 1

I need to prune zero length files from the directory or parse around "no file errors" to find actual errors. Another solution would be to output to NUL, but this too splits the build process. It would be nice to have a solution within the source itself.

Maybe "format null" could not produce a file?

[EDIT] found several solutions to delete an empty file:
https://stackoverflow.com/questions/9378972/how-do-i-detect-and-delete-a-file-if-it-is-empty-using-a-windows-batch-file

_________________
¯\(°_o)/¯ unlicense.org

Last edited by bitRAKE on 22 Jan 2020, 03:11; edited 1 time in total

27 Feb 2019, 01:27

bitRAKE

Joined: 21 Jul 2003
Posts: 2808
Location: dank orb

bitRAKE

bitRAKE wrote:

Next I try to verify some data: There is list of cube sums at https://arxiv.org/abs/1604.07746v1

The answer is 42 !

https://www.youtube.com/watch?v=ASoz_NuIvP0

[EDIT] Found!

https://youtu.be/zyG8Vlw5aAw

_________________
¯\(°_o)/¯ unlicense.org

Last edited by bitRAKE on 06 Sep 2019, 17:05; edited 1 time in total

13 Mar 2019, 02:00

bitRAKE

Joined: 21 Jul 2003
Posts: 2808
Location: dank orb

bitRAKE

Tried to encapsulate commandline option testing to something like:

Code:

OPTION "s","silent"
        bts [Options.FLAGS],FLAG_SILENT
END OPTION

OPTION "h","help"
        mov rax,[.pArgv]
        push qword [rax]
        lea rdx,[HelpMessage]
        call STD_OUTPUT_HANDLE__wsprintfA
        pop rax
END OPTION

... which resulted in the following try ...

Code:

Options.count = 0

macro OPTION text&
        local skip
        macro END.OPTION!
                        label skip.0
                esc end macro
                end repeat
                purge END.OPTION
        end macro

        Options.count = Options.count + 1
        repeat 1,i:Options.count
        esc macro Options.i
                iterate txt,text
                        virtual at 1
                                ; rely on DU to convert UTF8 to widechar
                                du txt
                                load temp: $-1 from $$
                        end virtual
                        if % = %%
                                skip.temp = 1
                        end if
                        repeat ((bsr temp) shr 4) + 2
Display "0"+%% ; 1?
                                if % = %%
                                        if % and 1
                                                cmp word [rsi+2*(%+1)],temp
                                        else
                                                cmp dword [rsi+2*(%+1)],temp
                                        end if
                                        if skip.temp
                                                ; fall through to process, if txt is last alternative
                                                jnz skip.0
                                        else
                                                ; jump over alternatives to process
                                                jz skip.dont
                                        end if
                                else if ~ (% and 1)
                                        cmp dword [rsi+2*(%+2)],temp and $FFFFFFFF
                                        temp = temp shr 32
                                        if skip.temp
                                                ; if txt is last alternative skip process
                                                jnz skip.0
                                        else
                                                ; try next alternative
                                                jnz skip.%
                                        end if
                                end if
                        end repeat
                        label skip.%
                end iterate
                label skip.dont
end macro

macro __OPTIONS
        postpone ?
        repeat Options.count
                Options.%
        end repeat
        end postpone
end macro

Can't seem to get this to work as expected. Completely baffled how REPEAT ?+2 could result in %%=1.

_________________
¯\(°_o)/¯ unlicense.org

14 Jul 2019, 11:45

Tomasz Grysztar
Assembly Artist

Joined: 16 Jun 2003
Posts: 7543
Location: Kraków, Poland

Tomasz Grysztar

bitRAKE wrote:

Can't seem to get this to work as expected. Completely baffled how REPEAT ?+2 could result in %%=1.

When you define a macro inside a REPEAT block, the "%%" in the text of the inner macro is replaced with a number. So the body of your macro contains a hard-coded number in place of every occurrence of "%%" (and the same goes for "%").

To make matters worse, "%" and "%%" are global parameters (not limited by a scope, as long as you are inside some repeated block, they have a value), so even encapsulating the macro definition would not save you here.

14 Jul 2019, 11:52

Tomasz Grysztar
Assembly Artist

Joined: 16 Jun 2003
Posts: 7543
Location: Kraków, Poland

Tomasz Grysztar

A reduced sample that demonstrates the problem:

Code:

repeat 1,i:1
        macro Options.i
                iterate txt, 'a','b','c'
                        display '0'+%%
                end iterate
        end macro
end repeat

Options.1

And a kind of a messy solution:

Code:

macro preserve_counters? %:%, %%:%%
        macro end?.preserve_counters?
                end match
        end macro
        outscope match %:%%, %:%%
end macro


repeat 1,i:1
        preserve_counters
                macro Options.i
                        iterate txt, 'a','b','c'
                                display '0'+%%
                        end iterate
                end macro
        end preserve_counters
end repeat

Options.1

But in this case I think it would be better to just get rid of the outer REPEAT, for example by using MATCH to extract the name of macro to define from a symbolic variable (you could even maintain Options.count as a symbolic variable).

14 Jul 2019, 12:14

bitRAKE

Joined: 21 Jul 2003
Posts: 2808
Location: dank orb

bitRAKE

Since I didn't need the count, I went with something similar to:

Code:

postpone ?
OPTIONS
end postpone

macro OPTIONS
end macro

macro OPTION text&
        macro END.OPTION!
                esc end macro
                purge END.OPTION
        end macro

        esc macro OPTIONS
                OPTIONS
                iterate txt, text
                        display "0"+%,txt
                end iterate
                display 13,10
end macro


OPTION 'a','b','c'

END OPTION

OPTION 'x','y','z'

END OPTION

This is less efficient perhaps?

_________________
¯\(°_o)/¯ unlicense.org

30 Jul 2019, 14:27

bitRAKE

Joined: 21 Jul 2003
Posts: 2808
Location: dank orb

bitRAKE

Code:

; add to string list in sorted order
macro sort_into str_list*,text*&
        local inserted

        iterate t0, text
        inserted = 0
        repeat 1,k0:t0
                match S,str_list
                iterate sN, S
                        if inserted
                                str_list reequ str_list,sN
                        else if % = 1
                                repeat 1,kN:sN
                                        if k0 < kN
                                                str_list reequ t0,sN
                                                inserted = 1
                                        else
                                                str_list reequ sN
                                        end if
                                end repeat
                        else if % = %% ; not 1
                                repeat 1,kN:sN
                                        if k0 < kN
                                                str_list reequ str_list,t0,sN
                                        else
                                                str_list reequ str_list,sN,t0
                                        end if
                                end repeat
                        else
                                repeat 1,kN:sN
                                        if k0 < kN
                                                str_list reequ str_list,t0,sN
                                                inserted = 1
                                        else
                                                str_list reequ str_list,sN
                                        end if
                                end repeat
                        end if
                end iterate
                end match
        end repeat
        end iterate
end macro


my_list equ "6","A","k"
display 13,10,my_list

sort_into my_list,"1" ; test before
display 13,10,my_list

sort_into my_list,"y" ; test after
display 13,10,my_list

sort_into my_list,"x" ; test middle
display 13,10,my_list

; list merge sorted
temp_list equ "0","-","z","h"
match X,temp_list
        sort_into my_list,X
end match
display 13,10,my_list

_________________
¯\(°_o)/¯ unlicense.org

11 Dec 2019, 12:57

bitRAKE

Joined: 21 Jul 2003
Posts: 2808
Location: dank orb

bitRAKE

Code:

virtual at 16
calign::        ; AMD Family 17h, Model 30h-3Fh Recommended NOP encoding
        emit 16 : 00'00'00'00'00'84'1F'0F'66'66'66'66'66'66'66h
        emit 16 : 00'00'00'00'00'84'1F'0F'66'66'66'66'66'66h
        emit 16 : 00'00'00'00'00'84'1F'0F'66'66'66'66'66h
        emit 16 : 00'00'00'00'00'84'1F'0F'66'66'66'66h
        emit 16 : 00'00'00'00'00'84'1F'0F'66'66'66h
        emit 16 : 00'00'00'00'00'84'1F'0F'66'66h
        emit 16 : 00'00'00'00'00'84'1F'0F'66h
        emit 16 : 00'00'00'00'00'84'1F'0Fh
        emit 16 : 00'00'00'00'80'1F'0Fh
        emit 16 : 00'00'44'1F'0F'66h
        emit 16 : 00'00'44'1F'0Fh
        emit 16 : 00'40'1F'0Fh
        emit 16 : 00'1F'0Fh
        emit 16 : 90'66h
        emit 16 : 90h
end virtual

;macro code_align?
;       delta = 15-((0 scaleof $)+15) mod 16
;       if delta > 0
;               load dat : delta from calign : (16-delta) shl 4
;               emit delta : dat
;       end if
;end macro


calminstruction code_align? boundary:16
        check   boundary eq 16 & ($ relativeto 0 | ( $ relativeto PE.RELOCATION & PE.SECTION_ALIGNMENT mod boundary = 0 ))
        jyes    allowed
        arrange value, =err 'section not aligned enough'
        assemble value
        exit
    allowed:
        compute boundary, (boundary-1)-((0 scaleof $)+boundary-1) mod boundary
        check boundary eq 0
        jyes done
        arrange value, =load =dat : boundary =from =calign : (16-boundary) =shl 4
        assemble value
        arrange value, =emit boundary : =dat
        assemble value
    done:
end calminstruction


; just a test
repeat 16
        rb %
        code_align
end repeat
assert $=256

Every processor seems to have its own recommendation on code alignment to reduce pipeline resource use and stalls.

_________________
¯\(°_o)/¯ unlicense.org

24 Jan 2020, 20:42

Tomasz Grysztar
Assembly Artist

Joined: 16 Jun 2003
Posts: 7543
Location: Kraków, Poland

Tomasz Grysztar

While I've been testing assembly of HeavyThing with CALM-powered fasmg, I used this kind of conversion of its alignment macros:

Code:

struc bstr? bytes&
        virtual at 0
                db bytes
                load . : $ from 0
        end virtual
end struc

define aligncode aligncode
namespace aligncode
        ?15 bstr 0x66, 0xf, 0x1f, 0x84, 0x00, 0x00, 0x00, 0x00, 0x00, \
                 0x66, 0xf, 0x1f, 0x44, 0x00, 0x00
        ?14 bstr 0x66, 0xf, 0x1f, 0x84, 0x00, 0x00, 0x00, 0x00, 0x00, \
                 0xf, 0x1f, 0x44, 0x00, 0x00
        ?13 bstr 0x66, 0xf, 0x1f, 0x84, 0x00, 0x00, 0x00, 0x00, 0x00, \
                 0xf, 0x1f, 0x40, 0x00
        ?12 bstr 0x66, 0xf, 0x1f, 0x84, 0x00, 0x00, 0x00, 0x00, 0x00, \
                 0xf, 0x1f, 0x00
        ?11 bstr 0x66, 0xf, 0x1f, 0x84, 0x00, 0x00, 0x00, 0x00, 0x00, \
                 0x66, 0x90
        ?10 bstr 0x66, 0xf, 0x1f, 0x84, 0x00, 0x00, 0x00, 0x00, 0x00, \
                 0x90
        ?9 bstr 0x66, 0xf, 0x1f, 0x84, 0x00, 0x00, 0x00, 0x00, 0x00
        ?8 bstr 0xf, 0x1f, 0x84, 0x00, 0x00, 0x00, 0x00, 0x00
        ?7 bstr 0xf, 0x1f, 0x80, 0x00, 0x00, 0x00, 0x00
        ?6 bstr 0x66, 0xf, 0x1f, 0x44, 0x00, 0x00
        ?5 bstr 0xf, 0x1f, 0x44, 0x00, 0x00
        ?4 bstr 0xf, 0x1f, 0x40, 0x00
        ?3 bstr 0xf, 0x1f, 0x00
        ?2 bstr 0x66, 0x90
        ?1 bstr 0x90
        ?0 := ''
end namespace

define virtual          virtual
define end_virtual      end virtual

calminstruction aligncode alignment
        check   alignment
        jno     done
        local   a
        assemble virtual
        arrange alignment, =align alignment
        assemble alignment
        compute a, $ - $$
        assemble end_virtual
        check   a
        jno     done
        arrange a, =db =aligncode.a
        assemble a
    done:
end calminstruction

24 Jan 2020, 20:51

Goto page Previous 1, 2

< Last Thread | Next Thread >

Forum Rules:

You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You can download files in this forum