section ".data" data readable writeable
  section ".code" code readable executable
  ; some code
    

IMHO, it is not good idea to use separate code sections for every library. Even if you add one single byte, the section size becomes 512 bytes added to your .exe file.

Also, are you sure that empty sections causes crash?

For example if we have section only with uninitialized data this section will be zero length without problems.

I tested it with empty code section and empty data section and the file runs OK on my Win98 machine.

Or maybe this is some side effect - check your antivirus program or something...

Grouping the sections together and linking static libraries is the linker's job

format PE GUI 4.0
entry start

include '%fasminc%\win32a.inc'

section '.data' data readable writeable
;commenting the following nop creates an "invalid executable"
;according to Windows 2000 and XP

nop

section '.data' data readable writeable
  ParentClass          dd sizeof.WNDCLASSEX                       ;cbSize
                       dd CS_DBLCLKS or CS_HREDRAW or CS_VREDRAW  ;style
                       dd ParentWndProc                           ;lpfnWndProc
                       dd NULL                                    ;cbClsExtra
                       dd NULL                                    ;cbWndExtra
                       dd NULL                                    ;hInstance
                       dd NULL                                    ;hIcon
                       dd NULL                                    ;hCursor
                       dd COLOR_WINDOW+1                          ;hbrBackground
                       dd NULL                                    ;lpszMenu
                       dd szParentClass                           ;lpszClass
                       dd NULL                                    ;hIconSm


  szParentClass        db 'SKELETON',0
  szProgramTitle       db 'Skeleton FASM App',0

  hInstance            dd ?
  hwndParent           dd ?

  msg                  MSG

section '.code' code readable executable

proc ParentWndProc, hWnd,uMsg,wParam,lParam
        enter
        mov eax,[uMsg]
        cmp eax,WM_DESTROY
        je .Destroy
.Default:
        invoke DefWindowProc,[hWnd],[uMsg],[wParam],[lParam]
        return
.Destroy:
        invoke PostQuitMessage,0
        xor eax,eax
        return
endp

start:
        invoke GetModuleHandle,NULL
        mov [hInstance],eax

        invoke LoadIcon,NULL,IDI_APPLICATION
        mov [ParentClass+WNDCLASSEX.hIcon],eax

        invoke LoadCursor,0,IDC_ARROW
        mov [ParentClass+WNDCLASSEX.hCursor],eax

        mov eax,[hInstance]
        mov [ParentClass+WNDCLASSEX.hInstance],eax
        invoke RegisterClassEx,ParentClass

        invoke CreateWindowEx,0,szParentClass,szProgramTitle,\
          WS_VISIBLE+WS_OVERLAPPEDWINDOW,144,128,256,256,\
          NULL,NULL,[hInstance],NULL
        jmp @f
.MessageLoop:
        invoke TranslateMessage,msg
        invoke DispatchMessage,msg
@@:
        invoke GetMessage,msg,NULL,0,0
        test eax,eax
        jnz .MessageLoop
        invoke ExitProcess,[msg.wParam]

section '.idata' import data readable writeable

  library kernel,'KERNEL32.DLL',\
          user,'USER32.DLL'

  import kernel,\
         GetModuleHandle,'GetModuleHandleA',\
         ExitProcess,'ExitProcess'

  import user,\
         RegisterClassEx,'RegisterClassExA',\
         CreateWindowEx,'CreateWindowExA',\
         DefWindowProc,'DefWindowProcA',\
         GetMessage,'GetMessageA',\
         TranslateMessage,'TranslateMessage',\
         DispatchMessage,'DispatchMessageA',\
         SendMessage,'SendMessageA',\
         LoadCursor,'LoadCursorA',\
         LoadIcon,'LoadIconA',\
         LoadMenu,'LoadMenuA',\
         PostQuitMessage,'PostQuitMessage'
    

For linking static libraries, I'll agree to that. For grouping sections, I don't necessarily.