include 'win32ax.inc'
POOL_SIZE  = 1 * 1024*1024
ALLOC_SIZE = 64

.data
  pPool dd 0
  pHead dd 0
.code

; On error EAX=0
proc heap_init
  invoke  VirtualAlloc, NULL, POOL_SIZE, MEM_COMMIT, PAGE_READWRITE
  test    eax, eax
  mov     [pPool], eax
  mov     [pHead], eax
  jz      .exit

  mov     ecx, POOL_SIZE / ALLOC_SIZE - 1 ; Make sure that ecx will be 1 at least here

.loop:
  lea     edx, [eax+ALLOC_SIZE]
  mov     [eax], edx
  mov     eax, edx
  dec     ecx
  jnz     .loop

  mov     dword [eax], 0 ; Close list

.exit:
  ret
endp

; EAX=NULL on fail
proc heap_alloc
  mov     eax, [pHead]
  test    eax, eax
  jz      .exit

  mov     edx, [eax]
  mov     [pHead], edx

.exit:
  ret
endp

; pointer must be valid (a pointer that was already freed is considered invalid of course)
proc heap_free pointer
  mov     eax, [pointer]
  mov     edx, [pHead]
  mov     [eax], edx
  mov     [pHead], eax

  ret
endp

start:
  call    heap_init
  call    heap_alloc
  stdcall heap_free, eax

  invoke  MessageBox, 0, "Test", "No crash ", 0
  invoke  ExitProcess, 0
.end start    

bitRAKE: I'm mostly concerned on how to deal with the memory block and all pointers rather than how to allocate it at the moment, unless I missed something from your code.

macro getBlock reg0*,reg1*{
        mov reg0,reg1
        mov reg1,[reg1]
}
macro putBlock reg0*,reg1*{
        mov [reg0],reg1
        mov reg1,reg0
}    

(Looks like the same thing LocoDelAssembly posted - just in another form.)