Setup.exe (install shield)
data1.cab
data2.cab
Setup.ini
ikernel.ex_
data1.hdr
setup.inx
layout.bin
    

@DecodingItem$qpuc
@STKPassword$qpuc
@IsSTKCard$qv
@IsAutoMenuOn$qv
@EndDebug$qv
@BeginDebug$qv
@UpdateRecord$qpucucuci
@ReadRecord$qpucucuci
@UpdateBinary$qpucii
@ReadBinary$qpucii
@GetResponse$qpuci
@SelectFile$qus
@Verify$qucpuc
@IncomeingAPDU$qpuc
@OutgoingAPDU$qpuct1
@Disconnect$qv
@ConnectCard$qi
    

format PE GUI 4.0

include 'win32a.inc'

   RBufferLength = 32

   SETXOFF       = 1
   SETXON        = 2
   SETRTS        = 3
   CLRRTS        = 4
   SETDTR        = 5
   CLRDTR        = 6
   RESETDEV      = 7
   SETBREAK      = 8
   CLRBREAK      = 9

   PURGE_TXABORT = 00001h
   PURGE_RXABORT = 00002h
   PURGE_TXCLEAR = 00004h
   PURGE_RXCLEAR = 00008h
   PURGE_ALL     = 0000Fh

struc DCB {
  .DCBlength                      dd 28
  .BaudRate                       dd 9600
  .Flags                          dd 11100000h
  .wReserved                      dw 0
  .XonLim                         dw 100h
  .XoffLim                        dw 40h
  .ByteSize                       db 8            ;8 bits
  .Parity                         db 2            ;Even
  .StopBits                       db 2            ;2 stop bits
  .XonChar                        db 11h
  .XoffChar                       db 13h
  .ErrorChar                      db 0
  .EofChar                        db 0
  .EvtChar                        db 0
  .wReserved1                     dw 0
}
struc COMMTIMEOUTS {
  .ReadIntervalTimeout            dd 0
  .ReadTotalTimeoutMultiplier     dd 0
  .ReadTotalTimeoutConstant       dd 10           ;seems to be 10ms even if set to 1
  .WriteTotalTimeoutMultiplier    dd 1
  .WriteTotalTimeoutConstant      dd 50
}

section '.code' code readable executable

        invoke CreateFile,CPName,GENERIC_WRITE+GENERIC_READ,0,0,OPEN_EXISTING,0,0  ;Open Comm Port
        mov [CPHandle],eax
        cmp eax,-1
        je NoComms

        invoke GetCommTimeouts,[CPHandle],OriginalCOMMTIMEOUTS  ;Save original state
        cmp eax,0                                               ;
        je exit                                                 ;
                                                                ;
        invoke GetCommState,[CPHandle],OriginalDCB              ;
        cmp eax,0
        je exit

        invoke SetCommState,[CPHandle],SimDCB
        invoke SetCommTimeouts,[CPHandle],SimCOMMTIMEOUTS
        invoke EscapeCommFunction,[CPHandle],SETDTR              ;probably not required
        invoke EscapeCommFunction,[CPHandle],SETRTS              ;Reset SIM
        invoke Sleep,10
        invoke PurgeComm,[CPHandle],PURGE_ALL                    ;Clear buffers

        invoke GetTickCount                                      ;Start timing
        mov    [StartTime],eax
        invoke EscapeCommFunction,[CPHandle],CLRRTS              ;Clear Reset (SIM RST High)

again:
        invoke ReadFile,[CPHandle],[RBufferP],RBufferLength,ActualBytes,0
        cmp eax,0
        je ReadError

        inc    [Counts]
        mov    eax,[ActualBytes]
        cmp    [Counts],50                                       ;50x 10ms, 500ms should be enough
        jg     TimeOut                                           ;longer than 0.5s
        cmp    eax,0
        jz     again                                             ;no bytes received

        add    [RBufferP],eax
        cmp    [RBufferP],RBuffer+RBufferLength
        jge    BufferFull
        cmp    [RBufferP],RBuffer+2
        jl     again                                             ;Get a least the first two bytes

        cmp    [DataLength],2
        jne    CheckLength

        mov    al,byte [RBuffer+1]                               ;Work out number of expected bytes
        mov    ebx,BitCount                                      ;number of bits per byte
        mov    dl,al
        shr    al,4
        xlatb                                                    ;al = number of high nibble bits set
        and    dl,0fh
        add    dl,al
        add    byte [DataLength],dl                              ;expected data length

CheckLength:
        mov    eax,[RBufferP]
        sub    eax,RBuffer
        cmp    eax,[DataLength]
        jl     again                                             ;Have all bytes been received?

        invoke GetTickCount
        sub    eax,[StartTime]                                   ;How long it took to get an ATR

        invoke wsprintf,AccessTime,wsformat,eax

BytesReceived:
        mov    ecx,[DataLength]
        mov    esi,RBuffer                                      ;Hex...
        mov    edi,Result                                       ;converted to Ascii
Conv:   lodsb
        mov    dl,al
        shr    al,4
        cmp    al,9
        jle    Dec1
        add    al,7
Dec1:
        add    al,30h
        stosb
        mov    al,dl
        and    al,0fh
        cmp    al,9
        jle     Dec2
        add    al,7
Dec2:
        add    al,30h
        stosb
        dec    ecx
        jnz    Conv
        xor    al,al
        stosb                                                   ;end string with a zero

        invoke MessageBox,NULL,AccessTime,CPName,MB_OK          ;Display ATR result,
        jmp    ReInstate                                        ;no checks for legitimacy

BufferFull:
        invoke MessageBox,NULL,TooMuchData,CPName,MB_OK
        jmp    ReInstate

TimeOut:
        invoke MessageBox,NULL,TooLong,CPName,MB_OK

ReInstate:
        invoke SetCommState,[CPHandle],OriginalDCB              ;Restore original state
        invoke SetCommTimeouts,[CPHandle],OriginalCOMMTIMEOUTS  ;

exit:   invoke  CloseHandle,[CPHandle]
        invoke  ExitProcess,0
NoComms:
        invoke MessageBox,NULL,CommFailure,CPName,MB_OK
        invoke  ExitProcess,0

section '.data' data readable writeable

CPHandle                dd 0
ActualBytes             dd 0
Counts                  dd 0
StartTime               dd 0
DataLength              dd 2
RBufferP                dd RBuffer
BitCount                db 0,1,1,2,1,2,2,3,1,2,2,3,2,3,3,4
SimDCB                  DCB
OriginalDCB             DCB
SimCOMMTIMEOUTS         COMMTIMEOUTS
OriginalCOMMTIMEOUTS    COMMTIMEOUTS

wsformat                db 'ATR reponse time = %4u ms.   ',0dh,0dh,0
Lenwsformat=$-wsformat
CPName                  db 'COM4',0                             ;Comport SIM card is on
TooLong                 db 'Timed out >500ms',0
CommFailure             db 'Unable to open port',0
TooMuchData             db 'Too much data',0
ReadError               db 'Error reading data',0

AccessTime              rb Lenwsformat
Result                  rb RBufferLength*2
                        rb 1
RBuffer                 rb RBufferLength*2

section '.idata' import data readable writeable

 library kernel32,'KERNEL32.DLL',\
         user32,'USER32.DLL'

 import kernel32,\
        Sleep,'Sleep',\
        GetTickCount,'GetTickCount',\
        CreateFile,'CreateFileA',\
        ReadFile,'ReadFile',\
        CloseHandle,'CloseHandle',\
        GetCommState,'GetCommState',\
        GetCommTimeouts,'GetCommTimeouts',\
        SetCommTimeouts,'SetCommTimeouts',\
        SetCommState,'SetCommState',\
        PurgeComm,'PurgeComm',\
        EscapeCommFunction,'EscapeCommFunction',\
        ExitProcess,'ExitProcess'

 import user32,\
        wsprintf,'wsprintfA',\
        MessageBox,'MessageBoxA'