; MEMID5.ASM -- rugxulo AT gmail DOT com
; public domain ("nenies proprajxo")
;
; Check out FASM:  http://board.flatassembler.net

org 100h

BREAK equ int3
;SPLIT equ aam

macro SPLIT { 
      mov cl,4 
      shl ax,cl 
      shr al,cl 
}

macro UPPERCASE b { 
      cmp b,'a' 
      jb @f 
      cmp b,'z' 
      ja @f 
      and b,0DFh 
@@: 
}

macro ERR a { 
      cmp byte [opt],a 
      jnz @f 
      mov word [error],bp 
@@: 
}

macro HELP { 
      mov dx,help_msg 
      call puts 
      mov byte [error],255 
}

CR=13
LF=10
TAB=9

Opts:
        mov si,80h
        mov cl,byte[si]
        xor ch,ch
        jcxz is286
@@:
        inc si
        cmp byte [si],20h
        loope @b
@@:
        cmp byte [si],'/'
        jnz @f
        inc si
        jmp @b
@@:
        UPPERCASE byte [si]
        push ax
        mov al,byte [si]
        mov byte [opt],al
        pop ax
        cmp byte [si],'?'
        jnz @f
        mov byte [si],'H'
@@:
        cmp byte [si],'H'
        jnz @f
        HELP
        jmp Fino
@@:
is286:
        mov ax,sp
        cmp ax,sp
        jnz VCPI
PMODE:
        smsw ax
        test al,1
        jz DPMI
        mov dx,pmode_msg
        call puts
        mov bp,1
        ERR 'P'
DPMI:
        mov ax,1687h
        int 2Fh
        test ax,ax
        jnz VCPI
        mov bp,dx
        cmp bp,100h
        jnz @f
        mov bp,100
@@:
        push dx dx
        mov dx,dpmi_msg
        call puts
        pop ax
        xor ah,ah
        aam
        xchg ah,al
        pop bx
        xor bl,bl
        or ax,bx
        call ver
        ERR 'D'
VCPI:
        mov ax,3567h
        int 21h
        mov ax,es
        test ax,ax
        jnz @f
        test bx,bx
        jz EMM386
@@:
        mov ax,0DE00h
        int 67h
        test ax,ax
        jnz EMM386
        mov dx,vcpi_msg
        call puts
        xchg ax,bx
        call adjust
        call ver
        ERR 'V'
EMM386:
        mov ax,3D00h
        mov dx,emm386_id
        int 21h
        jc XMS
        xchg ax,bx
        mov ax,4400h
        int 21h
        jc XMS
        test dx,80h
        jz XMS
EMS:
        mov ah,40h
        int 67h
        test ah,ah
        jnz XMS
        mov dx,emm386_msg
        call puts
        mov ah,46h
        int 67h
        SPLIT
        call adjust
        call ver
        ERR 'E'
XMS:
        mov ax,4300h
        int 2Fh
        cmp al,80h
        jnz crlf
        mov dx,xms_msg
        call puts
        mov ax,4310h
        int 2Fh
        mov word [xms_addr],bx
        mov word [xms_addr+2],es
        xor ah,ah
        call dword [xms_addr]
        call adjust
        call ver
        ERR 'X'
crlf:
        mov dl,13
        call putc
        mov dl,10
        call puts2
Fino:
        mov ah,4Ch
        mov al,byte [error]
        int 21h
puts:
        mov ah,9
puts2:
        int 21h
        ret
putc:
        mov ah,2
        jmp puts2
ver:
        xchg dx,ax
        or dx,'00'
        xchg dh,dl
        call putc
        mov dl,'.'
        call putc
        xchg dh,dl
        call putc
        mov dl,' '
        call putc
        ret
adjust:
        push ax
        aad
        mov bp,ax
        pop ax
        ret

error dw 4C00h
help_msg db CR,LF,'MEMID 0.5 -- returns errorlevel',CR,LF,CR,LF
         db '/h',TAB,'help',  TAB,'255',     CR,LF
         db '/p',TAB,'Pmode?',TAB,'0  | 1',  CR,LF
         db '/d',TAB,'DPMI?', TAB,'90 | 100',CR,LF
         db '/v',TAB,'VCPI?', TAB,'10 | ??', CR,LF
         db '/e',TAB,'EMS?',  TAB,'32 | 40', CR,LF
         db '/x',TAB,'XMS?',  TAB,'20 | 30', CR,LF,'$'

pmode_msg db 'PMODE $'
dpmi_msg db 'DPMI $'
vcpi_msg db 'VCPI $'
emm386_id db 'EMMXXXX0',0
emm386_msg db 'EMS $'
xms_msg db 'XMS $'

xms_addr rb 4
opt rb 1

; EOF
    

EMS 4.0 XMS 3.0

DPMI 0.9 XMS 2.0

; public domain, free for any use ("nenies proprajxo")

Good! There is a small inconsistency in there, however: if EMS is OFF (no EMMXXXX0 device exists). VCPI can still be enabled.

(according to VCPI.DOC) ...

          lea dx,emm_name      ; open EMM device, read-only
          mov ax,3D00h
          int 21h
          jc short no_vcpi     ; branch if error
    

rugxulo wrote:

; public domain, free for any use ("nenies proprajxo")

rugxulo, are you Esperantist?

Jes (malgraux mia malofta uzo). Cxu ankaux vi scipovas gxin cxu nur vi konas gxin pro la pola doktoro kiu kreis gxin?

BTW. ruĝulo, are you red-haired (ginger)?

... but I have never seen such a situation (and wouldn't know how to setup such). If you know how, please tell me. (The VCPI.DOC says VCPI is a superset of an EMS driver, so I assumed it was always available if EMS was found.)