;
; ACRACK - Altimate (almost) CRACKer for APACK'ed files
; (CL) Copyleft 2007 Public Domain - ABUSE at YOUR own risk !!!
;

format binary as "EXE"
use16

; Code size: $1'0000 File size: $1'0020
; Reserve: 0 Stack: $1000

org 0

 db "MZ"
 dw $20           ; Last block
 dw $81           ; Blocks
 db 0,0           ; No relocs
 db 2,0           ; Header size
 dw $0100         ; Min
 dw $0100         ; Max
 dw $1000         ; Stack segment
 dw $1000         ; Stack size / pointer in bytes !!!
 db 0,0,0,0,0,0   ; CHK, IP, CS 
 dw $1C           ; Useless reloc offset
 db 0,0           ; Useless "overlay"
 db 0,0,0,0       ; Padding / empty reloc

org 0

   push cs
   push cs
   pop  ds
   pop  es

   mov   dx,tx4
   mov   ah,9
   int   $21

   mov   ax,[$0110]
   cmp   ax,$5757         ; Check it
   jnz   llcompatfail
   mov   byte [$0110],$90 ; Crack it

   call  $0100            ; Decompress it
   sub   di,$0100         ; Uncompressed size
   mov   [$FE],di

   xor   cx,cx
   mov   dx,tx0
   mov   ah,$3C
   int   $21              ; Create / open for write
   jc    llsavfail

   mov   bx,ax            ; Handle
   mov   ah,$40
   mov   cx,[$FE]         ; Size
   mov   dx,$0100

   int   $21              ; Save
   jc    llsavfail

   mov   ah,$3E
   int   $21
   jc    llsavfail        ; Close

   mov   dx,tx1
   pushw $4C00
   jmp   short llexit
;------------------

llcompatfail:
    mov   dx,tx2
    pushw $4CFF
    jmp   short llexit
;---------------------

llsavfail:
    mov   dx,tx3
    pushw $4CFF

llexit:
    mov  ah,9
    int  $21
    mov  dx,tx5
    int  $21
    pop  ax
    int  $21
;-----------

tx0: db 'CRACKED.COM',0
tx1: db '$'
tx2: db 'Compatibility $'
tx3: db 'Save failure $'
tx4: db 'ACRACK - Altimate (almost) CRACKer for APACK',$27,'ed files',$0D,$0A
     db '(CL) 2007 P.D. - ABUSE at YOUR own risk !!' ; pass 
tx5: db $0D,$0A,$0D,$0A,$24,0,0