i've seen something that due to docs should be great debugger, called 386swat, buti don't have DOS anymore to try it.

- support for MMX instructions and register dump

It supports disassembly of the full 386, 387, 486, Pentium, and Pentium Pro CPU instruction sets through the Pentium MMX & SSE instructions

@echo off
REM Tested on DR-DOS 7.03 and FreeDOS Odin 0.71
REM w/ VALX 2.21.1.203 w/ GRDB 7.4, HHsed 1.5, and
REM my own TEST.ASM (beta) w/ ArrowASM 2.00c
REM
REM VALX and GRDB (Get Real Debugger): by LadSoft (David Lindauer)
REM http://members.tripod.com/~ladsoft
REM
REM Or, try 386SWAT (Bob Smith)
REM http://www.sudleyplace.com
REM   'debugit test.asm'
REM   'asm /ml test;'
REM   'val /co /nci /map test;'
REM   'devload d:\whatever\386swat.lod SYMSIZE=32000'
REM   'swatrun test.com c:\here\there /n'
REM
REM rugxulo@NOSPAM.PLEASE.bellsouth.net
REM Friday, September 9, 2005   12:07am

if "%1"=="" goto error
if "%SED%"=="" set sed=hhsed

%SED% -n -e "/^[; ]/d;s/\(.*\) [dD][bwdBWD] .*/public \1/p" %1 > mydebug.inc
%SED% -n -e "s/^\([a-zA-Z0-9_][a-zA-Z0-9_]*\):.*/public \1/p" %1 >> mydebug.inc
ren %1 *.del
for %%a in (*.del) do %SED% -e "1{/mydebug/!s/.*/include mydebug.inc\n&/;}" %%a >> %1
erase *.del
echo.

echo 'asm /ml myprog;'
echo 'valx /co /nci /sym myprog;' (or /ex for .EXE)
echo 'grdb myprog.com' (or whatever)
echo.
echo (inside GRDB)
echo '$$$ #' where # = sizeof(mydebug.inc) in hex
echo '$$l myprog.sym'

REM (for 16-bit .COM, we don't need 32-bit regs or instructions)
echo '?o -32 -wr -sc +sk' 

REM .COM files start at 100h
echo 'u ip'

echo.
goto exit

:error
echo.
echo Huh? Where's the .ASM filename??
echo.

:exit
    

as i tried debug.exe it still supports only 8086 instruction set (possibly 80286) even in w2k (xp - do not know)

ndisasm is a good disassembler, also OpenWatcom C/C++ has its disassembler, which understands .obj files and a good debugger (with MMX, SSE support)...

@echo off
REM Tested on DR-DOS 7.03 Lite and (partially) WinXP Home SP2
REM rugxulo@NOSPAM.PLEASE.bellsouth.net
REM Monday, September 19, 2005   7:11pm

if not exist cm*.zip if not exist ext*.zip goto usage
if not exist %1.asm goto usage

if "%WATCOM%"=="" set PATH=.\binw;%PATH%
if "%WATCOM%"=="" set WATCOM=.

unzip32 -qqn cm*.zip
unzip32 -qqn ext*.zip

wasm.exe -d3 %1.asm
wlink debug all format dos com file %1.obj name %1.com
wd %1.com %2 %3 %4 %5 %6 %7 %8 %9
goto exit

:usage
echo.
echo  ftp://ftp.openwatcom.org/watcom/zips-1.3/
echo.
echo 1. ( CM_CORE_DOSWIN.ZIP )    867,335   (includes WLINK.EXE, WASM.EXE)
echo 2. ( CM_CORE_ALL.ZIP    )    115,098   ('' WLSYSTEM.LNK)
echo 3. ( CM_DBG_MISC1.ZIP   )    554,522   ('' WD.EXE)
echo 4. ( CM_DBG_ALL.ZIP     )     26,218   ('' CPP.PRS)
echo 5. ( EXT_DOS4GW.ZIP     )    268,440   ('' DOS4GW.EXE)
echo    ======================  1,831,613   (total bytes)
echo.
echo  These files above (at least!) are required.
echo.

:exit
    

also, a few hex editors (free ones) i have seen do it too.