UTF-8 support with macro

This macro, when defined at the beginning of program using the standard package of macros for Win32 programming, allows to use characters encoded with UTF-8 in the quoted strings (for example in resources), and they'll be properly converted to Unicode (note that fasmw is ASCII-based, so to enter such characters comfortably you need some editor with UTF-8 support, like Notepad in NT-based systems).

Code:

macro du [args]
 {
  common local ..count,..current,..byte,..wide
   virtual at 0
    db args
    ..count = $
   end virtual
   ..current = 0
   repeat ..count
    if ..current<..count
     virtual at 0
     db args
     load ..byte byte from ..current
     if ..byte<0C0h
      ..wide = ..byte
     else if ..byte<0E0h
      ..wide = (..byte and 11111b) shl 6
      ..current = ..current+1
      load ..byte byte from ..current
      ..wide = ..wide + (..byte and 111111b)
     else if ..byte<0F0h
      ..wide = (..byte and 1111b) shl 12
      ..current = ..current+1
      load ..byte byte from ..current
      ..wide = ..wide + (..byte and 111111b) shl 6
      ..current = ..current+1
      load ..byte byte from ..current
      ..wide = ..wide + (..byte and 111111b)
     else
      ..wide = ..byte ; higher currently unsupported
     end if
     ..current = ..current+1
     end virtual
     dw ..wide
    end if
   end repeat
 }