Replace al to al,ah,bl,bh,cl,ch,dl,dh million times

Index > Main > Replace al to al,ah,bl,bh,cl,ch,dl,dh million times

Author

Thread

Fastestcodes

Joined: 13 Jun 2022
Posts: 75

Fastestcodes 17 Aug 2022, 10:02

code:
mov al,
mov al,
mov al,
mov al,
mov al,
mov al,
mov al,
mov al,

That I want:
mov al,
mov ah,
mov bl,
mov bh,
mov cl,
mov ch,
mov dl,
mov dh,

What is the best solution?

17 Aug 2022, 10:02

Tomasz Grysztar

Joined: 16 Jun 2003
Posts: 8351
Location: Kraków, Poland

Tomasz Grysztar 17 Aug 2022, 10:41

To re-use an existing solution, you could take my old fasmg as a preprocessor example, and use it with a preprocessing macros looking like this:

Code:

iterate reg, al,ah,bl,bh,cl,ch,dl,dh
        TARGET#% equ reg
end iterate

COUNTER = 0

namespace MACROS

        macro mov? args&
                match =al =, src, args
                        repeat 1, i:COUNTER+1
                                match dest, TARGET#i
                                        emit mov dest, src
                                end match
                        end repeat
                        COUNTER = (COUNTER + 1) and 111b
                else
                        emit mov args
                end match
        end macro

end namespace

The script then takes the source like:

Code:

mov al,1
mov al,2
mov al,3
mov al,4
mov al,5
mov al,6
mov al,7
mov al,8
mov al,9
mov al,10
mov al,11
mov al,12
mov al,13
mov al,14
mov al,15
mov al,16

and converts it (purely as text) into:

Code:

mov al, 1
mov ah, 2
mov bl, 3
mov bh, 4
mov cl, 5
mov ch, 6
mov dl, 7
mov dh, 8
mov al, 9
mov ah, 10
mov bl, 11
mov bh, 12
mov cl, 13
mov ch, 14
mov dl, 15
mov dh, 16

That example is quite old. With new facilities like CALM and the two-argument variant of INCLUDE (that had been added to fasmg since then) a much cleaner framework could be made. But the old one still works and can be used with not much additional effort.

17 Aug 2022, 10:41

Tomasz Grysztar

Joined: 16 Jun 2003
Posts: 8351
Location: Kraków, Poland

Tomasz Grysztar 17 Aug 2022, 10:48

And since you mentioned a million replacements, I tested it with a simple seed that makes me a million MOVs:

Code:

repeat 1000000
        db 'mov al,0',10
end repeat

Here's how it went on my laptop:

Code:

C:\asm\fasmglab\preprocess>fasmg seed.asm source.asm
flat assembler  version g.jmhx
1 pass, 0.5 seconds, 9000000 bytes.

C:\asm\fasmglab\preprocess>fasmg preprocess.asm -isource='source.asm' final.asm
flat assembler  version g.jmhx
1 pass, 12.7 seconds, 11000000 bytes.

Of course, unless your source text is actually much more complex, you could do it all with nothing more than regular expressions.

17 Aug 2022, 10:48

Fastestcodes

Joined: 13 Jun 2022
Posts: 75

Fastestcodes 17 Aug 2022, 12:24

https://board.flatassembler.net/topic.php?t=22374
"La00:
pop eax
and al,0feh
and ah,0feh
and bl,0feh
and bh,0feh
and cl,0feh
and ch,0feh
and dl,0feh
and dh,0feh; if al=00h, 8Byte least significant bit will be 0,0,0,0,0,0,0,0
jmp Lawm

La01:
....;if al=01h, 8Byte least significant bit will be 0,0,0,0,0,0,0,1

Laff:
...; if al=0ffh, 8Byte least significant bit will be 1,1,1,1,1,1,1,1

Lawm: ;write to mem
mov [edi],al
mov [edi+1],ah
...
mov [edi+7],dh"

If I replace the 1s or 0s "or al,01h" and "and al,0feh" all regs will be "al".

17 Aug 2022, 12:24

Fastestcodes

Joined: 13 Jun 2022
Posts: 75

Fastestcodes 17 Aug 2022, 13:03

Code:

Replace 0 with "and al,0feh0A", replace 1 with "or al,01h0A", replace j with "jmp Lawm0A"

17 Aug 2022, 13:03

bitRAKE

Joined: 21 Jul 2003
Posts: 4020
Location: vpcmpistri

bitRAKE 17 Aug 2022, 13:25

With fasmg we could combine something like macomics' suggestion with the dispatcher:

Code:

L_start:
        and dword [edi],0xFEFEFEFE
        and dword [edi+4],0xFEFEFEFE


... (dispatch) ...


        MAGIC   := 0x8040201008040201
        MASK    := 0x8080808080808080
        repeat 256, v:0
                A = ((MAGIC *v) and MASK) shr 7
                A = A bswap 8
                L#v:
                        if A and 0xFFFFFFFF
                                or dword [edi], A and 0xFFFFFFFF
                        end if
                        if A shr 32
                                or dword [edi+4], A shr 32
                        end if
                        jmp L_end
        end repeat

L_end:
        add edi,8

... all bits are assumed zero, and then set bits as needed. Could move the bit clearing into the branch code as well - clearing only as needed.

_________________
¯\(°_o)/¯ “languages are not safe - uses can be” Bjarne Stroustrup

17 Aug 2022, 13:25

bitRAKE

Joined: 21 Jul 2003
Posts: 4020
Location: vpcmpistri

bitRAKE 17 Aug 2022, 14:12

Code:

; RCX bytes of RSI into low bits of bytes in RDI
steganography:
        lea rbp,[.end]
        lea rbx,[.L0]
.start:
        and dword [rdi],0xFEFEFEFE
        and dword [rdi+4],0xFEFEFEFE

        .RANGE := 15
        movzx eax,byte [rsi]
        add rsi,1
        imul eax,.RANGE
        lea rax,[rax+rbx]
        jmp rax

        MAGIC   := 0x8040201008040201
        MASK    := 0x8080808080808080
        repeat 256, v:0
                A = ((MAGIC * v) and MASK) shr 7
                A = A bswap 8
                .L#v:
                        if A and 0xFFFFFFFF
                                or dword [rdi], A and 0xFFFFFFFF
                        end if
                        if A shr 32
                                or dword [rdi+4], A shr 32
                        end if
                        jmp rbp ; .end

                if $ - .L#v > .RANGE
                        err 'branch larger than desired range'
                end if
                while $ - .L#v <> .RANGE
                        db 0x90
                end while
        end repeat

.end:   add rdi,8
        dec rcx
        jnz .start
        retn

repeat 1, len:$ - steganography
        display 9,`len,' bytes for steganography'
end repeat

... is maybe what you are aiming for? Did some other stuff to reduce the code size to under 4k. SIMD methods will be faster.

17 Aug 2022, 14:12

Overclick

Joined: 11 Jul 2020
Posts: 669
Location: Ukraine

Overclick 17 Aug 2022, 19:56

movdqa xmm0,xword[yourdataplace]
pand xmm0,xword[yourmask]
...
movdqa xword[yourdataplace],xmm0

You don't need to separate the data stream by bytes, just use SSE

17 Aug 2022, 19:56

Fastestcodes

Joined: 13 Jun 2022
Posts: 75

Fastestcodes 22 Aug 2022, 09:23

Overclick wrote:

movdqa xmm0,xword[yourdataplace]
pand xmm0,xword[yourmask]
...
movdqa xword[yourdataplace],xmm0

You don't need to separate the data stream by bytes, just use SSE

Pand on 16Byte for lsb=0 0xfeff...
Por on 16Byte for lsb=1 0x0001...

22 Aug 2022, 09:23

bitRAKE

Joined: 21 Jul 2003
Posts: 4020
Location: vpcmpistri

bitRAKE 24 Aug 2022, 13:08

I haven't done any testing - just brainstorming with my first coffee ...

Code:

m256_bbits      mm256 db 0x01,0x02,0x04,0x08,0x10,0x20,0x40,0x80
m256_01         mm256 db 1

; 3 temp reg, 2 const regs = unroll of four

        vmovntdqa ymm14,[m256_bbits]
        vmovntdqa ymm15,[m256_01]
        align 16,0x90
@@:     iterate <_0,    _1,     _B>,\
                ymm0,   ymm1,   ymm2,\
                ymm3,   ymm4,   ymm5,\
                ymm6,   ymm7,   ymm8,\
                ymm9,   ymm10,  ymm11

                vpbroadcastb    _B, [rsi + % - 1]
                vmovdqa         _1, [rdi + 32*% - 32]
                vpand           _B, _B, ymm14
                vpandn          _0, ymm15, _1
                vpor            _1, ymm15, _1
                vpcmpeqb        _B, _B, ymm14
                vpblendvb       _0, _0, _1, _B
                vmovntdq        [rdi + 32*% - 32], _0
                .UNROLL = %%
        end iterate
        add rsi,.UNROLL
        add rdi,32*.UNROLL
        cmp rsi,rcx
        jnz @B

struc mm256 values&
        label .:32
        values
        granularity = bsr ($ - .)
        assert 6 > granularity
        repeat (1 shl (5 - granularity)) - 1
                values
        end repeat
        assert ($ - .) = sizeof .
end struc

_________________
¯\(°_o)/¯ “languages are not safe - uses can be” Bjarne Stroustrup

24 Aug 2022, 13:08

< Last Thread | Next Thread >

Forum Rules:

You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You can download files in this forum