I need the "extrn" label so that it can link to the entry point of my Pascal program.

Since FASM generates binary image directly, I end up using NASM temporarily for this project, and it has been done, a "hello world" OS kernel written in Pascal!

format binary as 'img'
;version 15/03/2023 04:02
;version 04/06/2019 13.54
;version 01/05/2014 01:29
;version 27/11/2007 01:48
;bootcode:

;;; BEGIN OF MBR

;BOOTRELOC:   ;uncomment to test reloc

masterbootrecord:
use16
        org 7c00h
        mov ax,cs
        mov ss,ax
        mov ds,ax
        mov [bootdrive],dl

;copy bootloader from 0000h:7c00h to 0020h:7c00h
;linear 07c00h to 07e00h
;this is used to load boot sectors from other partitions or drives.
if defined BOOTRELOC

        mov ax,20h
        mov es,ax
        mov bx,200h
        mov di,7c00h
  @@:
        dec bx
        jl @f
        mov al,[di+bx]
        mov [es:di+bx],al
        jmp @b
  @@:

;and jump to the recopy.

        jmp 20h:@f
otherdrive db 80h   ;set this to any drive n°
  @@:

;at this point, we can load another boot sector
;from another drive with code like this:
if defined otherdrive
        mov ah,0eh
        mov al,'B' ;print B each time it's reloaded
        int 10h
        mov dl,[otherdrive]
        mov ax,21h   ;load 1 sector
        mov cx,1
        xor dh,dh
        mov bx,7c0h
        mov es,bx
        xor bx,bx
        int 13h
        jmp 0:7c00h
end if  ;otherdrive


end if  ;BOOTRELOC

;load the system from sector 2 to lowmem
        mov cx,secondstage.packets
@@:
        push cx
        mov ah,42h
        mov dl,[bootdrive]
        mov si,dap
        int 13h
        add [dap.fptr+2],(40h*512)/16
        add dword[dap.lba],40h
        pop cx
        loop @b

        xor ax,ax
        mov ss,ax
        mov ds,ax
        jmp 0:secondstage.org

dap:
        db 10h,0
.cnt    dw 40h ;32k
.fptr   dd secondstage.seg:0
.lba    dd 1,0

        rb 509-($-$$)
bootdrive:
        db 0
        dw 0aa55h

;;; END OF MBR

include 'secondstage.inc'

if ~definite secondstage
secondstage:
.seg=800h
.org=.seg*16  ;starts at 32k
.packets=1


        org .org
        mov ax,ds
        mov es,ax
        mov ax,3
        int 10h

        mov si,.str
        call prints

        jmp $

.str:   db 'nothing to boot',0

prints:
        mov ah,0eh
@@:
        lodsb
        or al,al
        je @f
        int 10h
        jmp @b
@@:
        ret


end if  ;secondstage
    

secondstage:
.seg = 800h
.org = .seg*16  ;starts at 32k
.packets = 19   ;640 - 32k

        org .org
        call SMAP.query
        jmp kernel
include 'smap.inc'
kernel:
        mov si,.str
        call prints

        jmp entrypoint

.str:   db 'something booted, and you can read the SMAP',0

prints:
        mov ah,0eh
@@:
        lodsb
        or al,al
        je @f
        int 10h
        jmp @b
@@:
        ret

entrypoint:
        jmp $
    

in fact, it's better to don't use protected mode during boot process.

better to load a lot of stuff using bios and then, start the os

And isn't always possible, as I've mentioned if the kernel doesn't fit into 7C00h - A0000h, then it's never going to work.

Only you have a little more memory. You can use addresses 0x00600 .. { int 12h ~ ax * 1024 - 1 }

as bios is the only reliable thing on every pc.
uefi is not always there

don't you think switching back to unrealmode can be better cause you can load files with bios, and copy them anywhere without returning to pm? i think it's better but maybe i'm wrong.

maybe v86 is a good way too, as it can be called from pm and act like a sandbox.