I mean bug, that reveals itself only in WINE.

JohnFound wrote:

I mean bug, that reveals itself only in WINE.

If so then that would be WINE's bug.

;============ Check graphics in console window
format PE console 4.0
entry start

include 'win32a.inc'
struct CONSOLE_CURSOR_INFO
  dwSize    dd      ?
  bVisible  dd      ?
ends
struct SMALL_RECT
  Left      dw      ?
  Top       dw      ?
  Right     dw      ?
  Bottom    dw      ?
ends
section '.data' data readable writeable 

NameConsole db "For exit press 'Esc'",0
bmp_path  db 'dragon.bmp',0
hOut      dd ?
hWnd      dd ?
hDC       dd ?
hbitmap   dd ?
memDC     dd ?
ScreenX   dd ?
ScreenY   dd ?
bi        BITMAP
cci       CONSOLE_CURSOR_INFO
ConsoleWindow   SMALL_RECT
;---------------------------------------------
section '.code' code readable executable
  start:
        xor     ebx,ebx
        invoke  FreeConsole
        invoke  AllocConsole
        invoke  SetConsoleTitle,NameConsole
        invoke  GetStdHandle,STD_OUTPUT_HANDLE
        mov     [hOut],eax
        invoke  LoadImage,400000h,bmp_path,ebx,ebx,ebx,LR_LOADFROMFILE
        mov     [hbitmap],eax
        lea     edi,[bi]
        invoke  GetObject,eax,sizeof.BITMAP,edi
        movzx   eax,[bi.bmBitsPixel]
        shr     eax,3                   ; eax=bmBitsPixel/8
        mul     [bi.bmWidth]
        mul     [bi.bmHeight]
        push    eax     ;eax=bmpBitsPixel*bmpWidth*bmBitsPixel/8
        invoke  GetProcessHeap
        invoke  HeapAlloc,eax,HEAP_NO_SERIALIZE
        mov     eax,[bi.bmWidth]
        shr     eax,3
        mov     [ScreenX],eax             ; eax=bmWidth/8
        mov     edx,357913941           ; edx=(2^32)/12
        mov     eax,[bi.bmHeight]
        mul     edx
        mov     [ScreenY],edx             ; edx=bmHeight/12
        invoke  GetLargestConsoleWindowSize,[hOut]
        lea     edi,[ConsoleWindow]
        mov     [edi],ebx
        sub     eax, [ScreenX]
        sbb     edx, edx
        and     ax, dx
        dec     eax
        add     eax, [ScreenX]
        mov     [edi+SMALL_RECT.Right],ax
        shr     eax, 16
        sub     eax,[ScreenY]
        sbb     edx, edx
        and     eax, edx
        dec     eax
        add     eax, [ScreenY]
        mov     [edi+SMALL_RECT.Bottom],ax
        invoke  SetConsoleWindowInfo,[hOut],TRUE,edi
        mov     eax,[ScreenY]
        shl     eax,16                  ; Coord.y=ScreenY
        add     eax,[ScreenX]             ; Coord.x=ScreenX
        invoke  SetConsoleScreenBufferSize,[hOut],eax
        lea     edi,[cci]
        invoke  GetConsoleCursorInfo,[hOut],edi
        mov     [edi+CONSOLE_CURSOR_INFO.bVisible],ebx      ; FALSE
        invoke  SetConsoleCursorInfo,[hOut],edi
        invoke  CloseHandle,[hOut]
        invoke GetConsoleWindow
        mov     [hWnd],eax
        invoke GetDC,eax
        mov     [hDC],eax
        invoke  CreateCompatibleDC,eax
        mov     [memDC],eax
        invoke  SelectObject,eax,[hbitmap]
@@:     invoke  Sleep,150
        invoke  BitBlt,[hDC],ebx,ebx,[bi.bmWidth],[bi.bmHeight],\
                      [memDC],ebx,ebx,SRCCOPY
        invoke  GetAsyncKeyState,VK_ESCAPE
; Determine whether a key is up or down
        test    eax, 8000h
        jz      @b
exit:   invoke  DeleteObject,[hbitmap]
        invoke  ReleaseDC,[hWnd],[hDC]
        invoke  DeleteDC,[memDC]
        invoke  FreeConsole
        invoke  ExitProcess,ebx

;---------------------------------------------
section '.idata' import data readable writeable
  library kernel32,'kernel32.dll',\
          user32,'user32.dll',\
          gdi32, 'gdi32.dll'
  include 'include\api\kernel32.inc'
  include 'include\api\user32.inc'
  include 'include\api\gdi32.inc'    

invoke  ReleaseDC,[hDC],[hWnd] 
    

invoke  ReleaseDC,[hWnd],[hDC]