; C.ASM -- 122-byte .ZIP viewer!   
;          reads local headers
;          only outputs filenames to STDOUT
;
; public domain, free for any use, no credit necessary
; assemble w/ FASM 1.67.14
;
; Thank you, Lord Jesus, for your kindness and mercy, etc.   
;
; rugxulo AT bellsouth DOT net
; Monday, November 6, 2006   11:37am

CR=13
LF=10

STDOUT=1

org 100h

Komenco:
        mov ax,3D00h
        mov si,80h
        cmp byte [si+1],CR
        jz Fino
        xor bh,bh
        mov bl,[si]
        mov byte [si+bx+1],bh
        lea dx,[si+2]
        int 21h
        jc Fino
        xchg bx,ax
Ekzamenu:
        mov cx,local_header_size
        mov dx,local_header
        call read_file
        mov di,filesize_compressed
        cmp word [di-18],'PK'
        jnz Fino
;        cmp word [di-16],0201h
;        jz Fino
        cmp word [di-16],0403h
        jnz Fino
        push word [di+2]
        push word [di]
        mov cx,[di+8]
        push cx
        add cx,[di+10]
        mov dx,buffer
        call read_file
        pop cx
        mov ah,40h
        push bx
        mov bx,STDOUT
        int 21h
        pop bx
        mov ah,2
        mov dl,CR
        int 21h
        mov dl,LF
        int 21h
        pop dx
        pop cx
        test dx,dx
        jnz Bonege
        jcxz Ekzamenu
Bonege:
        mov ax,4201h
        int 21h
        jnc Ekzamenu
Fino:
        mov ax,4C00h
        int 21h

; read_file
read_file:
        mov ah,3Fh
        int 21h
        jc Fino
        cmp ax,cx
        jnz Fino
read_file_ret:
        ret

local_header:
   id rb 4
   version rb 2
   bitfield rb 2
   compression rb 2
   filetime rb 2
   filedate rb 2
   crc rb 4
   filesize_compressed rb 4
   filesize_uncompressed rb 4
   filename_length rb 2
   extra_field_length rb 2

local_header_size = $-local_header

buffer:

; EOF
    

[ WinXP ] Sun 11/05/2006>av AV19TEMP.ZIP /i! /m! /p /l!

AV19TEMP.ZIP

av19.asm       16,049        (74,475)          Oct,28,2006  09:24:06a  [Defl-X]
avlazy.bat     866           (2,461)           Jan,03,2006  09:49:28a  [Defl-X]
av19.com       4,585         (4,585)           Oct,28,2006  09:31:06a  [Stored]
izappnfo.txt   38,981        (166,297)         May,28,2004  06:20:00p  [Defl-X]
all4one.bat    85            (147)             Oct,29,2004  09:25:38p  [Defl-N]
one4all.bat    66            (66)              Oct,27,2004  08:03:16p  [Stored]
av186.asm      13,183        (65,416)          Jul,07,2005  10:44:20p  [Defl-X]
debugit.bat    998           (1,869)           Oct,07,2005  11:51:16p  [Defl-X]
zip630.txt     34,010        (136,852)         Oct,07,2006  06:52:54p  [Defl-X]
jmp2ret.bat    713           (1,685)           Aug,16,2006  12:46:36p  [Defl-X]

10 items: 0 dirs + 10 files
109,536 bytes (453,853 unzipped)
Created by ZIP 2.3 : DOS, OS/2, WinNT FAT

[ WinXP ] Sun 11/05/2006>scrndump
    

AV 0.19 (October 28, 2006)
rugxulo AT bellsouth DOT net
Usage:  av /z:cXi c:\dir\ /E myfile.zip

/c !  print archive Comment after view  /d !  print Dirs only, not files
/e    print numbers in kb (kb = 1024)   /f !  print only Files, not dirs
/h    Help screen  (/? also works)      /i !  list numitems & size totals Info
/k !  print archive Komment only        /l !  do not List name of opened file
/m !  print compr. Method nums (! sub-) /n    print CRLF after every fname
/o    no colors                         /p !  no Pause if screen is full
/q !  Quiet mode (summary info only)    /r !  clear or Reset to CO80 then list
/s(.asm) ! Search for fnames w/ ".asm"  /u    no commas
/x !  toggle printing numbers in heX    /y !+ wait after view or until kbhit
/z:   multiple options  (/z:icp!)
    

; C02.ASM -- 254-byte .ZIP viewer!   
;            (successor to the 122-byte "filenames-only" .ZIP viewer)
;
; public domain, free for any use, no credit necessary
; assemble w/ FASM 1.67.14  (http://www.flatassembler.net)
;
; God listens, God loves, God forgives, God helps ... thanks, God!   
;
; rugxulo AT bellsouth DOT net
;
; Wednesday, November 15, 2006   6:58pm
;
;
;     +===========+
;     | Bugfixes: |
;     +===========+
;        ! a zero-byte file is not always a DIR!
;          - rare but needed fixing (e.g., GNU/DJGPP sed: SED415S.ZIP)
;            - also! needed extra PUSH/POP for my XP (P4 2.52 Ghz) cpu
;              - seems to be needed only on Win XP Home SP2 (Dell A05 BIOS)
;                - DR-DOS 7.03 (P166), MS-DOS 6.22 (486 Sx/25) both work
;                  with or without it  
;        ! the .BAT was broken (oops, doh, oy, eek, wah)
;          - it was sometimes wrongly reporting success!  ;-(
;
;     +===========+
;     | Features: |
;     +===========+
;        + small (duh, that's the whole point!)
;        + written in FASM (which is FOSS/good/fast/small, etc.)
;          - TODO:  write sed scripts to convert to NASM, Octasm, etc.
;        + written in pure 8086 asm (no 386+ required)
;        + liberal license (or lack thereof ... (ab)use for whatever!)
;        + outputs names & sizes (w/ commas!) to STDOUT (redirectable)
;          + preserves filenames' case (upper, lower, mixed, whatever)
;          + now prints the .ZIP file's name itself first (hi, Dex!)
;        + always exits with errorlevel of zero (just to be nice)
;        - only reads local headers (not "Central Dir Structure")
;        - doesn't handle data descriptor (oh well, that's rare anyways)
;        - that's all!  it doesn't do anything else!  
;
;     +==============+
;     | Misc. Notes: |
;     +==============+
;        = to find *only* directories:
;             c02 myfile.zip | sed -n "/\/$/{N;p;}"
;
;        = to count files and dirs:
;             c02 myfile.zip | sed -n "1,2d;n;p;" | sed -n "$="
;
;     +=========+
;     | Caveat: |
;     +=========+
;        = if optimizing this further, use this .BAT to make sure
;          the resulting info outputted is the same):
;
; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
; @echo off
; REM Tested on DR-DOS 7.03 Lite
; REM
; REM !!! FIXED !!!  
;
; if "%1"=="/fc" goto test
;
; for %%a in (*.zip) do call %0 /fc %%a
; goto end
;
; :test
; shift
; c02-old.com %1>old
; c02.com %1>new
; fc old new
;
; :end
; for %%f in (old new) do if exist %%f del %%f
; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
;
;

;short equ byte                        ; uncomment for FASM < 1.65.20
                                       ;   (this prevents 386+ jumps)

CR=13                                  ; carriage return
LF=10                                  ; line feed

TAB=9
COMMA=','
SLASH='/'

org 100h

Komenco:
        mov ax,3D00h
        mov si,81h
        cmp byte [si],CR               ; end of cmdline
        jz short FinoFino
        xor bh,bh
        mov bl,[si-1]                  ; cmdline length (ignores CR)
        mov byte [si+bx],bh            ; change CR to 0 for int 21h,3Dh
        lea dx,[si+1]                  ;  (makes argv[1] into ASCIIZ)
        lea cx,[bx-1]                  ; CX = length - 1 (' ' after 'c02')

        int 21h                        ; open file for reading
        jc short FinoFino

        push ax                        ; save file handle
        mov si,dx
        call eldonu                    ; output .ZIP file's name
        call crlf
        call crlf                      ; output '\n' twice
        pop bx                         ; restore handle (for read_file)

Cxerpu:
        mov cx,local_header_size
        mov dx,local_header
        call read_file                 ; read in local header

        mov di,filesize_compressed

        cmp word [di-18],'PK'          ; verify if is a .ZIP file
        jnz short FinoFino
;        cmp word [di-16],0201h         ; if reached CDS, then quit
;        jz short Fino
        cmp word [di-16],0403h         ; if not local header, then quit
        jnz short FinoFino

        mov cx,[di+8]
        push cx                        ; save filename length
        add cx,[di+10]                 ; CX = fname len + extra field len
        mov dx,buffer
        call read_file                 ; read in filename and extra field
                                       ;  (to buffer)

        push dx
        mov ah,2
        mov dl,TAB                     ; output TAB (to ease readability)
        int 21h
        pop si                         ; SI = location of filename

        pop cx                         ; restore filename length
        call eldonu                    ; output filename

        mov cx,[di+2]
        mov dx,[di]                    ; CX:DX = size of compressed data

        test dx,dx
        jnz short Bonege
        test cx,cx                     ; is size of compressed data == 0 ?
        jnz short Bonege

        cmp al,SLASH                   ; if fname ends in '/', it's a DIR
        jnz short Bonege

Dosierujo:
        mov cx,dir_msg_size
        mov si,dir_msg+dir_msg_size-1  ; SI = offset of 'D' in 'DIR!' string
        clc                            ; clear carry flag
        pushf                          ; save flags for later
        jmp short Diru

FinoFino:
        jmp short Fino                 ; midway to Fino
                                       ;  (short jump range is exceeded)
CxerpuCxerpu:
        jmp short Cxerpu               ; midway to Cxerpu
                                       ;  (short jump range exceeded)
Bonege:
        mov ax,4201h                   ; move file pointer
        int 21h                        ;  (skip over compressed data,
        jc short Fino                  ;   if not a DIR)
        pushf

Grandeco:
        mov ax,[di+4]
        mov dx,[di+6]                  ; DX:AX = uncompressed file size

        push bx                        ; save file handle

bin2dec:
        mov cx,10                      ; output number in base 10 (decimal)

        mov di,buffer                  ; put ASCIIZ decimal string
;        mov si,di                      ;  w/ commas in buffer (backwards)
        xor bp,bp
bin2dec_start:
        xchg ax,dx
        push dx
        xor dx,dx                      ; convert word in AX to DX:AX (dword)
        div cx
        xchg ax,bx
        pop ax
        div cx
        xchg dx,bx

        or bl,'0'                      ; this only works for dec numbers!
;        push ax                        ; this works for dec or hex nums
;        xchg bl,al
;        mov bx,asciihex
;        xlatb                          ; translate digit to ASCII
;        xchg bl,al
;        pop ax

        inc bp
        mov byte [di],bl
        cmp bp,3
        jb short bin2dec_no_comma      ; comma_number = 3 (dec) or 4 (hex)

        inc di
        mov byte [di],COMMA
        xor bp,bp
bin2dec_no_comma:
        inc di
        test dx,dx
        jnz short bin2dec_start
        test ax,ax
        jnz short bin2dec_start
        dec di                         ; now DX:AX = 0
        cmp byte [di],COMMA            ; this will allow 3-digit numbers
        jz short bin2dec_bye           ;  not to be outputted w/ a comma
        inc di
bin2dec_bye:
        stosb
bin2dec_ret:

        pop bx                         ; restore file handle
        lea si,[di-2]                  ; SI = first digit in number
        lea cx,[di-buffer-1]           ; CX = size of number string

Diru:
        call crlf
        call eldonu_rev                ; output number ("buffer" in reverse)

Crlf_it:
        call crlf                      ; output \n
        popf                           ; restore flags
        jnc short CxerpuCxerpu         ; if not carry, get next header
Fino:
;        mov ax,4C00h                   ; closes files, returns errorlevel 0
;        int 21h
        int 20h                        ; thanks for your help, ATV   

; read_file
read_file:
        mov ah,3Fh                     ; BX = handle, CX = # bytes to read
        int 21h                        ; DX = buffer to read into
        jc short Fino                  ; carry flag means error
        cmp ax,cx
        jnz short Fino                 ; quit if # bytes read in != # bytes
read_file_ret:                         ;  requested to be read in
        ret

; crlf
crlf:                                  ; outputs \n to STDOUT
        mov ah,2
        mov dl,CR
        int 21h
        mov dl,LF
        int 21h
crlf_ret:
        ret

; eldonu_rev
eldonu_rev:                            ; outputs string at SI in reverse
        std                            ;  (redirectable)
                                       ; CX = size of string
; eldonu
eldonu:                                ; outputs string at SI (redirectable)
        mov ah,2                       ; CX = size of string
eldonu_denove:
        lodsb
        mov dl,al                      ; DL = char to output
        push ax                        ; * (need to save this on my XP cpu)
        int 21h
        pop ax                         ; * (PUSH/POP not needed on my P166)
        loop eldonu_denove             ; loop while CX is > 0

        cld                            ; clear direction flag
eldonu_ret:
        ret


;asciihex db '0123456789ABCDEF',0
dir_msg db '!RID'

dir_msg_size = $-dir_msg

local_header:
   id rb 4
   version rb 2
   bitfield rb 2
   compression rb 2
   filetime rb 2
   filedate rb 2
   crc rb 4
   filesize_compressed rb 4
   filesize_uncompressed rb 4
   filename_length rb 2
   extra_field_length rb 2

local_header_size = $-local_header

buffer:

; EOF
    

lines 689-
        mov ax,word ptr [pauzenum]
        shr ax,1                       ; pauzenum = pauzenum / 2
        mov word ptr [pauzenum],ax
new 689-
        shr word ptr [pauzenum],1      ; pauzenum = pauzenum / 2


lines 838-
        mov dx,bx
        shl dx,1
        shl bx,1
        shl bx,1
        add bx,dx
new 838-
        mov dx,bx
        shl bx,1
        add bx,dx
        shl bx,1        ;bx=bx*6

lines 1151-
        mov bx,dx
        mov cx,ax
        push cx
original number saved, but never used
(+ si=0 because 10 loop and all scrolled bits in di with reverse order!)
        rcr dx,1
        rcr ax,1
should be (don't want extra CF messing result)
        shr dx,1
        rcr ax,1

lines 1922-
        xor ah,ah
        mov al,byte ptr [columns]
        xor bh,bh
        mov bl,byte ptr [rows]
        mul bl
        mov cx,ax                      ; CX = rows*columns
        mov ax,bp
        mov es,ax
new 1922-
        mov al,byte ptr [columns]
        mul byte ptr [rows]
        mov cx,ax                      ; CX = rows*columns
        mov es,bp
    

; C.ASM -- 106-byte .ZIP viewer!
;          reads local headers, only prints filenames!
;
; public domain, free for any use
; assemble w/ FASM 1.67.14
;
; rugxulo AT bellsouth DOT net
; Friday, November 3, 2006   12:43am
;
; 7.nov.2006 some cleaning 126 -> 106 bytes by ATV

CR=13
LF=10

STDOUT=1

org 100h

Komenco:
        mov bx,0080h
        add bl,[bx]                 ; Get command line length
        mov [bx+1],bh               ; Make filename into ASCIIZ format.
        mov dx,0082h
        cmp bx,dx
        jb Fino
        mov ax,3D00h
        int 21h
        jc Fino
        xchg bx,ax
Ekzamenu:
        mov cx,30
        mov dx,local_header
        mov di,dx
        call read_file
        cmp word [di],'PK'
        jnz Fino
        cmp word [di+2],0201h
        jz Fino
;        cmp word [di+2],0403h
;        jnz Fino
        mov cx,[di+18+8]
        push cx
        add cx,[di+18+10]
        mov dx,buffer
        call read_file
        pop cx
        mov ah,40h
        push bx
        mov bx,STDOUT
        int 21h
        pop bx
        mov ah,2
        mov dl,CR
        int 21h
        mov dl,LF
        int 21h
        mov cx,[di+18+2]
        mov dx,[di+18]
        mov ax,4201h
        int 21h
        jnc Ekzamenu
Fino:
        int 20h

; read_file
read_file:
        mov ah,3Fh
        int 21h
        jc Fino
        cmp ax,cx
        jnz Fino
        ret

local_header:
   id rb 4
   version rw 1
   bitfield rw 1
   compression rw 1
   filetime rw 1
   filedate rw 1
   crc rw 2
   filesize_compressed rw 2
   filesize_uncompressed rw 2
   filename_length rw 1
   extra_field_length rw 1

buffer:

; EOF    

<EDIT>
Oops! Looks like you mistakenly changed int 21h,4Ch into int 20h. That would be fine except int 21h,4Ch also closes open files!

<EDIT #2>
Actually, the file still seems to be closed (at least in DOSBOX 0.65 and Win XP Home SP2 ... why?? Needs further testing, probably).
</EDIT #2>

</EDIT>

If you popped all things from stack, then you could even try to use "ret" instead "int 20". On clean stack "ret" in *.com files jumps to PSP:0h (if i remember correctly) which contains "int 20h" opcode. (Its something similar like in Windows executables)

polygon7 wrote:

If you popped all things from stack, then you could even try to use "ret" instead "int 20". On clean stack "ret" in *.com files jumps to PSP:0h (if i remember correctly) which contains "int 20h" opcode. (Its something similar like in Windows executables)

You may find details on it here.

Issue int 20h to exit from a program. This vector transfers to the
logic in DOS to restore the terminate address, the Ctrl-Break address,
and the critical error exit address to the values they had on entry to
the program. All the file buffers are flushed and all handles are
closed. You should close all files changed in length (see function
calls 10h and 3Eh) before issuing this interrupt. If the changed file
is not closed, its length, time, and date are not recorded correctly
in the directory.

by that I meant that there were times when I thought that *other* zippers are bloat and 7-zip is small (as a program, not as a compression method).

Now when I see that you can really unzip around 100 bytes wow - 7-zip feels bloat...

To throw another curveball:
...then there's the speed optimization issue.

P.S. These mini proggies of mine are not that impressive. I've seen better (tet, bd3, inv, selfdasm, wolf, smile256).