format binary as 'img' 
use16 
org 7c00h

;DATAPORT  = 0x1F0
;ERROR     = 0x1F1
;SECTORCNT = 0x1F2
;LBA_LOW   = 0x1F3
;LBA_MED   = 0x1F4
;LBA_HIGH  = 0x1F5
;DRIVE     = 0x1F6
;COMMAND   = 0x1F7
NULL       = 0
INREG      = "INREG"

macro inb port
 {
    if port <> "INREG"
       mov dx, port
    end if
    in al, dx
 }

macro outb port, value
 {
    if port <> "INREG"
       mov dx, port
    end if
    mov al, value
    out dx, al
 }

boot:
        cli
        display "Este código foi feito por A$M." ;On Brazilian Portuguese 

        push cs
        push cs
        pop ds
        pop es

        outb 0x1F1, NULL
        outb 0x1F2, 1
        LBA = 0x000001
        outb 0x1F3, LBA and 0xFF
        outb 0x1F4, (LBA shr 8) and 0xFF
        outb 0x1F5, (LBA shr 16) and 0xFF
        outb 0x1F6, 0xE0
        outb 0x1F7, 0x20 ;READ!

        mov ecx, 4
.loop1:
        inb INREG
        test al, 10000000b   ; Check BSY
        jnz short .retry
        test al, 00001000b   ; Check DRQ
        jnz short .data_ready
.retry:
        dec ecx
        jg short .loop1
.loop2:
        inb INREG
        test al, 10000000b   ; Check BSY
        jnz short .loop2
        test al, 00100001b   ; Check ERR and DF
        jnz short .fail
.data_ready:
        mov dx, 0x1F0
        mov cx, 256
        mov di, buffer
        rep insw       ; Read data to ES:DI
        inb 1F7h
        inb INREG      ; Waiting
        inb INREG      ; 400ns
        inb INREG

        mov si, done
        mov cx, 7
        mov dx, 0xE9
        rep outsb      ; 'Done!' message on BOCHS

        mov al, 1
        mov bh, 0
        mov bl, 2Fh
        mov cx, str_end - buffer
        mov dl, 0
        mov dh, 1
        mov bp, buffer
        mov ah, 13h
        int 10h
        hlt
        jmp $

.fail:
        mov al, 1
        mov bh, 0
        mov bl, 4Fh
        mov cx, error_end - error_str
        mov dl, 0
        mov dh, 1
        mov bp, error_str
        mov ah, 13h
        int 10h
        hlt
        jmp $

error_str db "ERROR!!!"
error_end:

done db "Done!",10,13

times 510-($-$$) db 0
                 dw 0aa55h

buffer:
db ' This is the proof that my code is absolutely right!!!!!!!!! \o/ '
str_end:
times 512-($-buffer) db 0
    

That covers basic read/write/identify, which is almost everything you'd normally need but the ATA specification has many more commands that cover power management, device status and reset/flushing. ATA also covers CD drives, so it has the abilty to check/lock/eject etc as well.

Nobody uses this in boot loader

You could try to implement your own file system, but it won't be readable to windows or other operating systems but your own