_start:
        ;; process priority class
        invoke  GetCurrentProcess
        push    0x100 ;;REALTIME_PRIORITY_CLASS
        push    eax
        invoke  SetPriorityClass
        ;; thread priority
        invoke  GetCurrentThread
        push    15 ;;THREAD_PRIORITY_TIME_CRITICAL
        push    eax
        invoke  SetThreadPriority
        ;; thread cpu core affinity
        invoke  GetCurrentThread
        push    2 ;;use CPU Core 2
        push    eax
        invoke  SetThreadAffinityMask
...
        push    strbuf
        push    strlen_optimized
        call    TimeSingleCall
...

TimeSingleCall: ;; (func, arg)
        push    ebp
        push    ebx
        push    esi
        push    edi
        mov     ebp, [esp + 20] ;; func
        mov     ebx, [esp + 24] ;; arg
        ;;
        xor     eax, eax
.warmup:
        add     ecx, eax
        sub     eax, 1
        jnz     .warmup
        ;;
        rdtsc
        mov     esi, eax
        mov     edi, edx
        push    ebx
        call    ebp
        rdtsc
        sub     eax, esi
        sbb     edx, edi
        ;;
        pop     edi
        pop     esi
        pop     ebx
        pop     ebp
        ret     8
    

* Execute a warmup loop right before the timing.

…Try to…

@revolution - If you are benchmarking a library function with global utility than ...

@baldr - Lets just throw together a 32bit real-time operating system to benchmark our string length optimizations

proc StrLenMMX, .ptrString    ; proc StrLen [hString]
begin
        push    ecx edx
        mov     eax, [.ptrString]

        pxor     mm1, mm1
        mov      ecx, eax
        mov      edx, eax
        and      ecx, -8
        and      eax, 7
        movq     mm0, [ecx]
        por      mm0, [.STRINGTBL+eax*8]

.inner:
        add      ecx, 8
        pcmpeqb  mm0, mm1
        packsswb mm0, mm0
        movd     eax, mm0
        movq     mm0, [ecx]
        test     eax, eax
        jz       .inner

        bsf      eax, eax
        shr      eax, 2
        lea      eax, [ecx+eax-8]
        sub      eax, edx

        emms
        pop     edx ecx
        return

.STRINGTBL dq   0, $ff, $ffff, $ffffff, $ffffffff, $ffffffffff, $ffffffffffff, $ffffffffffffff
endp    

Also, here is the question, is it appropriate to use MMX code in a general purpose library as FreshLib.

What is the reason for such strange behavior?

I think you should go the full way and have an XMMX 16byte at a time version. Using PCMPEQB + PTEST should keep the inner loop tight.

r22 wrote:

I think you should go the full way and have an XMMX 16byte at a time version. Using PCMPEQB + PTEST should keep the inner loop tight.

Teaser!

align 16
strlen_sse:
        mov     ecx, [esp + 4]
        pxor    xmm1, xmm1
        movdqu  xmm0, [ecx]
        mov     edx, ecx
        pcmpeqb xmm0, xmm1
        and     edx, 15
        add     ecx, 16
        pmovmskb eax, xmm0
        and     ecx, -16
        and eax, [STRLENMASK + edx * 4]
        jz .scan
        bsf     eax, eax
        sub     ecx, [esp + 4]
        lea     eax, [ecx + eax - 16]
        ret     4
align 16
.scan:
        movdqa  xmm0, [ecx]
        pcmpeqb xmm0, xmm1
        add     ecx, 16
        pmovmskb        eax, xmm0
        test    eax, eax
        jz      .scan
        bsf     eax, eax
        sub     ecx, [esp + 4]
        lea     eax, [ecx + eax - 16]
        ret 4

align 8
        STRLENMASK      dd      0x0000ffff, 0x00007fff, 0x00003fff, 0x00001fff, 0x00000fff, 0x000007ff, 0x000003ff, 0x000001ff, 0x000000ff, 0x0000007f, 0x0000003f, 0x0000001f, 0x0000000f, 0x00000007, 0x00000003, 0x00000001

    

align 16 
strlen_sse: 
        mov     ecx, [esp + 4] 
        movdqa  xmm2, [STRLENPTEST]
        pxor    xmm1, xmm1
        mov     edx, ecx 
        movdqu  xmm0, [ecx] 
        add     ecx, 16
        pcmpeqb xmm0, xmm1 
        and     ecx, -16 
        ptest   xmm0, xmm2
        jz      .scan 
        pmovmskb        eax, xmm0 
        sub     ecx, edx
        bsf     eax, eax 
        lea     eax, [ecx + eax - 16] 
        ret     4 
align 16 
.scan: 
        movdqa  xmm0, [ecx] 
        pcmpeqb xmm0, xmm1 
        add     ecx, 16 
        ptest   xmm0, xmm2
        jz      .scan 
        pmovmskb        eax, xmm0 
        sub     ecx, edx
        bsf     eax, eax 
        lea     eax, [ecx + eax - 16] 
        ret     4 
align 16
        STRLENPTEST     dq      0x8080808080808080, 0x8080808080808080