Counting 'X' and 'x' in string?

Index > Main > Counting 'X' and 'x' in string?

Author

Thread

TmX

Joined: 02 Mar 2006
Posts: 843
Location: Jakarta, Indonesia

TmX 02 Feb 2013, 08:38

I have a string "X12xxMXF", and I'd like to count the total occurences of 'X' and 'x'. Of course the expected result is 4

Code:

format PE console 4.0 

include 'win32a.inc' 

entry start 

section '.data' data readable 
blah db "X12xxMXF",0 
fmt db "%d",0 

section '.code' readable executable 
start: 
        mov ecx, 0 
        mov edx, 0

theLoop: 
        cmp ecx, 8
        jne process  
        je done
         
process: 
        lea  eax, [ecx + blah]
        cmp eax, 88 ; is eax = 'x' ? 
        je addOne 
        cmp eax, 120 ; is eax = 'X' ?
        je addOne
        inc ecx
        jmp theLoop 

addOne:
        inc edx
        jmp theLoop
         
done: 
        cinvoke printf, fmt, edx
        invoke  ExitProcess, 0 

section '.idata' data import readable writeable 
library kernel32, 'kernel32.dll',  msvcrt, 'msvcrt.dll' 
import kernel32, ExitProcess, 'ExitProcess' 
import msvcrt, printf, 'printf'

But my code yields 0. What's wrong here?

02 Feb 2013, 08:38

revolution
When all else fails, read the source

Joined: 24 Aug 2004
Posts: 20446
Location: In your JS exploiting you and your system

revolution 02 Feb 2013, 08:41

I think you might want to use:

Code:

movzx eax,byte[ecx+blah]

Instead of:

Code:

        lea  eax, [ecx + blah]

Or you could use:

Code:

cmp byte[eax],88

Or:

Code:

cmp byte[ecx+blah],88

02 Feb 2013, 08:41

baldr

Joined: 19 Mar 2008
Posts: 1651

baldr 02 Feb 2013, 11:18

Or even cmp byte [ecx+blah], 'X'. Wink

02 Feb 2013, 11:18

TmX

Joined: 02 Mar 2006
Posts: 843
Location: Jakarta, Indonesia

TmX 02 Feb 2013, 14:29

@revolution
The program gets stuck if either "lea eax, [ecx + blah]" or "movxz eax,byte [ecx + blah]" is used

@baldr
That yields 0. Weird Confused

02 Feb 2013, 14:29

revolution
When all else fails, read the source

Joined: 24 Aug 2004
Posts: 20446
Location: In your JS exploiting you and your system

revolution 02 Feb 2013, 14:35

Oh yeah. You'll have to add "inc ecx" in the addOne branch also.

That code needs to be rewritten, it jumps about too much and is difficult to follow.

02 Feb 2013, 14:35

AsmGuru62

Joined: 28 Jan 2004
Posts: 1670
Location: Toronto, Canada

AsmGuru62 02 Feb 2013, 15:43

Let me try:

Code:

        mov     esi, bla
        cld
        xor     eax, eax        ; EAX=0 -- To load characters from 'bla'
        xor     edx, edx        ; EDX=0 -- To count 'x' and 'X'

@@:
        lodsb                   ; AL<-[ESI] and ESI = ESI+1
        test    eax, eax
        jz      .print_counter  ; String ended with zero byte

        cmp     al, 'x'
        je      .count_me
        cmp     al, 'X'
        jne     @r

.count_me:
        inc     edx
        jmp     @r

.print_counter:
        ;
        ; ... print value in EDX here
        ;

02 Feb 2013, 15:43

TmX

Joined: 02 Mar 2006
Posts: 843
Location: Jakarta, Indonesia

TmX 02 Feb 2013, 15:47

@revolution
Still doesn't work. And why call "inc ecx" once again?
And sorry for the spaghetti code. I'll try rewrite it Embarassed

02 Feb 2013, 15:47

Picnic

Joined: 05 May 2007
Posts: 1403
Location: Piraeus, Greece

Picnic 02 Feb 2013, 16:15

TmX hi,

The program enters an infinite loop when it meets x or X because in that case the string index (ecx) is not updated.

02 Feb 2013, 16:15

TmX

Joined: 02 Mar 2006
Posts: 843
Location: Jakarta, Indonesia

TmX 02 Feb 2013, 16:55

Picnic wrote:

TmX hi,

The program enters an infinite loop when it meets x or X because in that case the string index (ecx) is not updated.

Ah, yes you are right.
Thanks. Now it works. Smile

02 Feb 2013, 16:55

< Last Thread | Next Thread >

Forum Rules:

You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You can download files in this forum