EC I/O synchronisation

Well my code is a bit messy at the moment, I've tried to clean up the 'read EC byte routine' to post but WinRing0 does the dirty work. We just need to pass the port number and either the data byte or storage location depending whether we're writing or reading. AFAIK there is no encapsulated CLI/STI.

Code:

;-------------------------------------------
proc    GetEcByte
        inc     [FailECB]                               ;Fail Flag for reading EC Byte

@@:
        invoke  ReadIoPortByteEx,66h,PByte              ;Read EC CMD/Status Register
        cmp     eax,0
        je      Fail                                    ;WinRing0.dll call failed

        mov     al,byte[PByte]
        and     al,7bh                                  ;Mask input bits
        cmp     al,0                                    ;Nothing pending
        je      @f
        cmp     al,8                                    ;Seems something writes a command to the EC and never finishes off
                                                        ;if we don't ignore this first time we never get any EC data.
                                                        ;Once we're talking all seems to go as expected !?!

        jne     Fail                                    ;Some other flag set so we just give up talking to the EC this time round
@@:

        invoke  WriteIoPortByteEx,66h,80h               ;Send 'Read Byte' command (0x80) to EC CMD/Status port 0x66 via  WingRing0.dll
        cmp     eax,0
        je      Fail                                    ;WinRing0.dll call failed

@@:
        invoke  ReadIoPortByteEx,66h,PByte              ;Read EC CMD/Status port 0x66 to PByte
        cmp     eax,0
        je      Fail
        mov     al,byte[PByte]
        and     al,1 shl 1                              ;Check if Bit 1 Input Buffer Full (IBF = 0) ie EC has read command
        jnz     @b

        invoke  WriteIoPortByteEx,62h,[OffSet]          ;Set Byte position Offset that we wish to read
        cmp     eax,0
        je      Fail

@@:
        invoke  ReadIoPortByteEx,66h,PByte
        cmp     eax,0
        je      Fail
        mov     al,byte[PByte]
        cmp     al,1 shl 1                              ;Check if Bit 1 Input Buffer Full (IBF = 0) ie EC has read command
                                                        ;Maybe we can skip this and just check for data
        jnz     @b

@@:
        invoke  ReadIoPortByteEx,66h,PByte
        cmp     eax,0
        je      Fail
        mov     al,byte[PByte]
        cmp     al,1 shl 0                              ;Check if Bit 0 Output Buffer Full (OBF = 1) ie EC has sent data byte
        jne     @b

        invoke  ReadIoPortByteEx,62h,ECByte             ;Read the data byte and save in ECByte
        cmp     eax,0
        je      Fail

        mov     [FailECB],0                             ;Clear the fail flag, ie we were successful
Fail:
        ret
endp
;-------------------------------------------

I think it's strange that when I go to read the EC cmd/status register for the first time bit 3 (CMD) is set which I think means something sent a command to the EC but never finished off.

I'm wondering if I need to use the ACPI GlobalLock to get the synchronisation while accessing the EC.

I did think about writing my own driver but quickly decided my ability and patience wasn't up to it so wimped out. Laughing

Besides WinRing0 seems to offer what I need plus it's certified too. Smile