Windows 32 Program Issue (Easy)

Hello,

Here is another small sample to experiment drewtoby.
Includes a handful of functions.

GetProcessHeap
CreateFile
GetFileSize
HeapAlloc
ReadFile
CloseHandle
HeapFree
Code:
            format pe console 4.0
            entry main

            include "win32ax.inc"

section ".idata" import data readable writeable

            library\
                kernel32, "KERNEL32.DLL",\
                user32, "USER32.DLL"

            include "\api\kernel32.inc"
            include "\api\user32.inc"


section ".code" code readable executable
main:

            stdcall loadfile, "somefile.txt"
            .if eax = 0
                ; api failed
                ; handle error
                ;
            .elseif eax = -1
                ; file not found
                ; handle error
                ;
            .else
                ; success
                ; EAX points to buffer
                ;
            .endif

            invoke ExitProcess, 0



proc loadfile uses ecx edx, path:dword

            local size dd 0
            local pfile dd 0
            local pmem dd 0
            local hheap dd 0
            local dtmp1 dd 0

            invoke GetProcessHeap
            test eax, eax
            jz .error

            mov [hheap], eax

            invoke CreateFile, [path], GENERIC_READ, 0, 0, OPEN_EXISTING, 0, 0
            cmp eax, -1
            je .notfound

            mov [pfile], eax

            invoke GetFileSize, [pfile], 0
            cmp eax, -1
            je .error

            mov [size], eax
            add eax, 100

            invoke HeapAlloc, [hheap],  HEAP_ZERO_MEMORY, eax
            test eax, eax
            jz .error

            mov [pmem], eax

            invoke ReadFile, [pfile], eax, [size], addr dtmp1, 0
            test eax, eax
            jz .error

            invoke CloseHandle, [pfile]
            test eax, eax
            jz .error

            mov eax, [pmem]
            ret

                .notfound:
            mov eax, -1
            ret

                .error:
            .if [pfile]
                invoke CloseHandle, [pfile]
            .endif

            .if [pmem]
                invoke HeapFree, [hheap], 0, [pmem]
            .endif

            xor eax, eax
            ret
endp