include '%fasminc%/macro/import32.inc'
        include '%fasminc%/macro/proc32.inc'

format PE
entry Main

        BUFFER_SIZE     equ 32
        FALSE           equ 0
        TRUE            equ (not FALSE)
        WM_GETTEXT      equ 0x000D
        NULL            equ 0


section '.code' code readable executable

        proc Main

                ; Top level window
                invoke FindWindowEx,NULL,NULL,pszCalcFrame,NULL
                or eax,eax
                jz @f

                ; Sub level window
                invoke FindWindowEx,eax,NULL,pszCalcFrame,NULL
                or eax,eax
                jz @f

                ; Scan
                invoke EnumChildWindows,eax,EnumChildWindowsProc,NULL

            @@:

                xor eax,eax

                ret
        endp

        proc EnumChildWindowsProc,hWnd,lParam
                push ebx

                invoke FindWindowEx,[hWnd],NULL,pszButton,NULL
                or eax,eax
                jz @f

            .next:

                mov ebx,eax

                invoke SendMessage,ebx,WM_GETTEXT,BUFFER_SIZE,buffer
                or eax,eax
                jz @f

                invoke lstrcmp,psz6,buffer
                or eax,eax
                jnz .fail

                push ecx esi edi

                mov ecx,8
                mov esi,pszHex
                mov edi,pszHexEnd

            .loop:

                dec ecx
                dec edi

                mov eax,ebx
                and eax,0x0F
                mov al,byte [esi+eax]
                mov byte [edi],al

                shr ebx,4

                or ecx,ecx
                jnz .loop

                pop edi esi ecx

                invoke MessageBox,NULL,pszHexOut,psz6,NULL

                jmp @f

            .fail:

                invoke FindWindowEx,[hWnd],ebx,pszButton,NULL

                jmp .next

            @@:

                xor eax,eax
                not eax

                pop ebx
                ret
        endp



section '.data' data readable writable

        pszCalculator   db 'Calculator',0
        pszCalcFrame    db 'CalcFrame',0
        pszButton       db 'Button',0
        psz6            db '6',0
        pszFmt          db '%08x',0
        pszHexOut       db '        '
        pszHexEnd       db 0
        pszHex          db '0123456789ABCDEF',0

        buffer  rb BUFFER_SIZE


section '.idata' import data readable writable

        library kernel32,'KERNEL32.DLL',\
                user32,'USER32.DLL'

        import kernel32,\
                lstrcmp,'lstrcmpA',\
                Sleep,'Sleep'

        import user32,\
                EnumChildWindows,'EnumChildWindows',\
                FindWindowEx,'FindWindowExA',\
                MessageBox,'MessageBoxA',\
                SendMessage,'SendMessageA'