2. When loading a file containing ZERO values, it aborts just at the earliest ZERO.

Solution: convert ZERO values into something else ("!")

This one is intentional - fasm always treated zero byte the same as EOF, and so fasm's editors do the same.

Why would anyone need zero byte in text file?

; FASMD.ASM 129'101 2016-02-05 21:53
; BD16'46BE'4E25'9B42'3620'8730'BB22'B45F

; flat assembler IDE for DOS/DPMI
; Copyright (c) 1999-2016, Tomasz Grysztar.
; All rights reserved.

      browser_directory_ok:
    cmp    byte [buffer+1],':'
    jne    browser_drive_ok   ; FWD
    mov    dl,[buffer]
    sub    dl,'A'
    cmp    dl,'Z'-'A'
    jbe    browser_change_drive ; FWD
    sub    dl,'a'-'A'

      browser_change_drive:
    mov    ah,0Eh
    int    21h

      browser_drive_ok:
    push    0                 ; PUSH here <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    cmp    dword [buffer],'..'
    jne    name_to_select_ok  ; FWD
    mov    edi,buffer+3000h
    mov    al,'\'

      find_last_directory_name:
    mov    esi,edi
    repne    scasb
    cmp    byte [edi],0
    jne    find_last_directory_name ; HANG here <<<<<<<<<<<<<<<<<<<<<<<<

    lea    ecx,[edi-1]
    sub    ecx,esi
    mov    edi,buffer+400h
    mov    [esp],ecx
    mov    ebx,upper_case_table

      get_name_to_select:
    lodsb
    xlatb
    stosb
    loop    get_name_to_select ; BCK SMALL LOOP

      name_to_select_ok:
    mov    edi,buffer+3000h
    call    get_current_directory
    jc    browser_drive_invalid ; JUMP OUT here <<<<<<<<<<<<<<<<<<<<<<<<
    cmp    byte [edi-2],'\'
    je    browser_new_path_ok ; FWD
    mov    word [edi-1],'\'

      browser_new_path_ok:
    call    make_list_of_files
    call    draw_browser_path
    mov    ebx,filename_buffer
    xor    eax,eax
    mov    [ebx+8],eax
    mov    [ebx+12],eax
    mov    [ebx+16],al
    mov    ebx,boxes
    mov    esi,[file_list]
    mov    [ebx+12],esi
    mov    ecx,[file_list_buffer_top]
    sub    ecx,esi
    shr    ecx,2
    mov    [ebx+6],cx
    xor    eax,eax
    mov    [ebx+8],eax
    mov    eax,esi
    pop    edx                ; POPE here <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

      find_name_to_select:
    cmp    eax,[file_list_buffer_top]
    je    file_list_selection_ok ; FWD
    mov    esi,[eax]
    add    esi,2
    mov    edi,buffer+400h
    mov    ecx,edx
    repe    cmpsb
    je    select_directory    ; FWD
    add    eax,4
    jmp    find_name_to_select
    ;-------------------------

      select_directory:
    sub    eax,[file_list]
    shr    eax,2
    mov    [ebx+8],ax

      file_list_selection_ok:
    test    byte [filename_buffer+1],1
    jnz    activate_file_input   ; BCK
    jmp    activate_file_browser ; BCK
    ;---------------------------

      browser_drive_invalid:
    mov    dl,[buffer+3000h]
    sub    dl,'A'
    cmp    dl,'Z'-'A'
    jbe    browser_restore_drive ; FWD
    sub    dl,'a'-'A'

      browser_restore_drive:
    mov    ah,0Eh
    int    21h
    pop    eax
    jmp    file_list_selection_ok ; BCK
    ;----------------------------
    

It hangs inside the "find_last_directory_name" loop. I suspect some sort of uninitialized variable or buffer.

ECX is uninitialized there. Please try with the correction I uploaded (it's added "or ecx,-1" after "mov al,'\'" instruction).

What about the possible stack-BUG?

; Patch for the CTL-BREAK-BUG

  wait_for_input:
        call    update_clock
        mov     ah, $11
        int     $16
        jz      wait_for_input    ; No key
        mov     ah, $10
        int     $16               ; AL ASCII code | AH scan code
        test    ax, ax            ; CMPNTQ AX, ZERO
        jz      wait_for_input    ; NOT valid, most likely [CTL]-[BREAK]
        ret
        ;----