org 7C00h
  xor ax, ax
  mov ds, ax

  mov ss, ax
  mov sp, 7C00h                 ; optional stack initialization

  mov al, dl
  test al, 80h
  jne .1
  add al, 'A'
  jmp .2
.1:
  and al, 7fh
  add al, 'C'
.2:
  mov si, drive
  mov [si], al
  call print                    ; display boot identifier
  
  mov si, disk_address_packet
  mov ah, 42h
  int 13h
  jnc .3
  mov si, error
  call print
  jmp $
.3:
  jmp 0:600h
print:
  mov ah, 0Eh
  xor bh, bh
.1:
  mov al, [si]
  lea si, [si+1]
  test al, al
  je .2
  int 10h
  jmp .1
.2:
  ret
disk_address_packet:
  dw 10h                        ; size of packet
  dw 1                          ; number of sectors
  dw 600h, 0                    ; buffer offset, segment
  dq 1                          ; LBA
drive:
  db 'A:', 13, 10, 0
error:
  db 'int 13h failed!', 0
times 446-($-$$)                  db 0
  db 0                          ; status
  db 0, 0, 0                    ; H, S, C of first block - not required
  db 0Bh                        ; partition type
  db 0, 0, 0                    ; H, S, C of last block - not required
  dd 63                         ; LBA of first sector
  dd 67521                      ; number of blocks (33 MB - hidden)
times (16*3)                      db 0
                                  dw 0AA55h
second_stage:
  test dl, 80h
  jne .1
  add dl, 'A'
  jmp .2
.1:
  and dl, 7fh
  add dl, 'C'
.2:
  push 0
  push 0FFFFh                   ; BIOS date at 0FFFF5h
  pop es
  mov cx, 8                     ; 02/03/11 - month/day/year
  mov si, 12                    ; start at last digit
.3:
  mov al, [es:si]
  lea si, [si-1]
  push ax
  sub cx, 1
  jne .3
  push WORD ' '
  push WORD ':'
  push dx
  xor bh, bh
.4:
  pop ax
  test al, al
  je .5
  mov ah, 0Eh
  int 10h
  jmp .4
.5:
  xor ax, ax
  int 16h
  int 19h
  times 512-($-second_stage)      db 0    

I see no stack being initialized.

I tested the code on some of my pc's. Some pc's boot ok,

but one pc wasn't even capable of detecting it as an existent drive. I have done usb booting on all of those pc's previously.

I have tested your code on Some of my PC's, all that used hdd emulation worked find.

But all that used floppy emulation did not boot.
By add a BPB they worked fine, just as i posted here
http://board.flatassembler.net/topic.php?t=12469

 mov si, disk_address_packet
  mov ah, 42h
  int 13h 
    

PS: You should also test for error after this

Code:

 mov si, disk_address_packet
  mov ah, 42h
  int 13h 
    

Dell D830, BIOS revision A15 (Dell?, graphical BIOS)
  C: 01/04/10
Lenovo SL500, BIOS version 1.19 (AMI)
    C: 12/25/08
HP nx7010, BIOS revision F.33 (HP?)
      C: 02/21/04
HP nc8230, BIOS revision F.11 (HP?)
      C: 05/01/06
HP 8510p, BIOS revision F.14 (HP?)
       C: 08/19/08
HP 6550b, BIOS revision F.02 (HP?, graphical BIOS)
       Does not work (BIOS date: 08/10/10)