;wait for a key
        mov     ah,$10
        int     $16
;e.. i'm weak in this sphere
    

format binary as 'img'
org 0x7c00
use16

start:
   cli
   mov       ax,0
   mov       ds,ax
   mov       es,ax
   mov       fs,ax
   mov       gs,ax
   mov       ss,ax
   ; [Edit] Added stack setup
   mov       sp,0x7c00 ; How's that, bitshifter?
   ; [/Edit]
   sti

   mov       si,didnt_do_hw
   call      print_ascii

   .again:
   mov       si,nl
   call      print_ascii
   mov       di,0x500
   call      scan_ascii
   cmp       ax,0
   je        .done
   mov       si,nl
   call      print_ascii
   mov       si,ax
   call      print_ascii
   jmp       .again

   .done:

   cli
   hlt

; al = char
; No output.
; No regs trashed.
print_char:
   push      ax bx
   mov       ah,0xe
   mov       bx,0x7
   int       0x10
   pop       bx ax
   ret

; No input.
; al = ascii char
; ah
get_char:
   mov       ah,0
   int       0x16
   ret

; si = char* buffer
; No output.
; No regs trashed.
print_ascii:
   push      si ax
   .next:
   lodsb
   cmp       al,0
   je        .end
   call      print_char
   jmp       .next
   .end:
   pop       ax si
   ret

; di = char* buffer
; ax = char* buffer
; No regs trashed.
scan_ascii:
   mov       ax,di
   push      ax
   .next:
   call      get_char
   cmp       al,0xd
   je        .end
   stosb
   call      print_char
   jmp       .next
   .end:
   mov       al,0
   stosb
   pop       ax
   sub       di,ax
   cmp       di,1
   je        .null
   ret
   .null:
   mov       ax,0
   ret

; I was going to use this, but turns out, I don't need it.  Oh well...
cmp_ascii:
   push      di si
   lodsb
   mov       ah,byte[di]
   sub       al,ah
   jne       .end
   cmp       ah,0
   jne       cmp_ascii
   .end:
   mov       ah,0
   pop       si di
   ret


didnt_do_hw db 'I didn',"'",'t do my homework.  I went to some random forum and prayed on innocent forummers and had them slave for me, to do my homework...  lolzzz',0xd,0xa,0xd,0xa,'Enter a string and I',"'",'ll echo it:',0
nl db 0xa,0xd,0

times 510 - ($ - $$) db 0
dw 0xaa55
    

It's bootable as a boot sector. To test it(the image below), set it as a floppy disk for a VM and boot the VM from the floppy.

...
cli
mov ss,ax
mov sp,0fffch ; 0ffffh, minus 2 = last word, minus 1 for alignment
sti
...