format PE console
entry start

include 'win32a.inc'

section '.data' data readable writable

_filename       db      "airplane.mp4.txt",0
_buffer         rb      464728
_handle         dd      ?
_console        dd      ?
_len            dd      ?

section '.code' code readable executable

start:
        push    0
        push    FILE_ATTRIBUTE_NORMAL
        push    OPEN_EXISTING
        push    0
        push    FILE_SHARE_READ
        push    GENERIC_READ
        push    _filename
        call    [CreateFile]
        cmp     eax, INVALID_HANDLE_VALUE
        mov     dword [_handle], eax
        je      .error
        push    STD_OUTPUT_HANDLE
        call    [GetStdHandle]
        mov     dword [_console], eax
        push    0
        push    _len
        push    464728
        push    _buffer
        push    dword [_handle]
        call    [ReadFile]
        test    eax, eax
        jz      .error     

        call    Play

.error:
        push    0
        call    [ExitProcess]

Play:
; String split iterator (bitRAKE)
;
; RDI:  string to scan
; RCX:  length of string in characters, >0
; AX:   character to split on

        lea     edi, [_buffer]
        mov     ecx, dword [_len]     

.scan:
        mov     al, '$'
        mov     esi, edi
        repnz   scasb
        push    edi
        jnz     .last
        sub     edi, 1               ; don't count the split character in length
.last:
        push    ecx
        sub     edi, esi             ; length without terminator
        ;jz skip

        push    0                    ; FUNCTION (address:RSI, length:RDI)
        push    0
        push    edi
        push    esi
        push    dword [_console]
        call    [WriteConsole]
        push    200
        call    [Sleep]

.skip:
        pop     ecx                 ; characters to go
        pop     edi                 ; start
        cmp     ecx, 0
        jz      .done
        jmp     .scan

.done:
        ret

section '.idata' import readable writable

 library kernel32, 'KERNEL32.DLL'

 import kernel32,\
        GetStdHandle, 'GetStdHandle', \
        WriteConsole, 'WriteConsoleA', \
        GetTickCount, 'GetTickCount', \
        Sleep, 'Sleep', \
        CreateFile, 'CreateFileA', \
        ReadFile, 'ReadFile', \
        ExitProcess,'ExitProcess'
    

format PE CONSOLE
entry start
include 'win32a.inc'

struct  CONSOLE_SCREEN_BUFFER_INFOEX
  cbSize                        dd ?
  dwSize                        dd ?    ; COORD  low 16bits X, high 16bits Y
  dwCursorPosition              dd ?    ; COORD
  wAttributes                   dw ?
  srWindow                      rd 2    ; SMALL_RECT (16bits) Left,Top,Right,Bottom
  dwMaximumWindowSize           dd ?    ; COORD
  wPopupSttributes              dw ?    ;
  bFullScreenSupported          dd ?    ; BOOL
  ColorTable                    rd 10h  ; COLORREF array
ends

;----------------------------------
section '.text' code readable executable

 SomeText       db 'Hello',10
 .len           = $ - SomeText

  start:
        push    STD_OUTPUT_HANDLE
        call    [GetStdHandle]
        mov     [hStdOut],eax

 ; Set console screen buffer size 128 characters by 40 characters
        mov     [CsbiEx.cbSize],sizeof.CONSOLE_SCREEN_BUFFER_INFOEX             ; Structure size
        push    CsbiEx
        push    [hStdOut]
        call    [GetConsoleScreenBufferInfoEx]                                  ; X,Y are in characters
        mov     [CsbiEx.dwSize],128 or (40 shl 16)                              ; Screen Buffer Size X,Y, increase as required
        mov     [CsbiEx.srWindow],0                                             ; Upper Left Buffer position X,Y
        mov     [CsbiEx.srWindow+4],128 or (40 shl 16)                          ; Lower Right Buffer position X,Y
        mov     [CsbiEx.dwMaximumWindowSize],128 or (40 shl 16)                 ; Max Size of Window X,Y
        invoke  SetConsoleScreenBufferInfoEx,[hStdOut],CsbiEx

 ; Offset position on display, if required
        call    [GetConsoleWindow]
        push    SWP_NOSIZE      ; Flags, dont change size
        push    0               ; Height, ignored with SWP_NOSIZE
        push    0               ; Width, ignored with SWP_NOSIZE
        push    10              ; Y Offset 10
        push    40              ; X Offset 40
        push    -1              ; HWND_TOPMOST (Z Order, change as required)
        push    eax             ; Handle from GetConsoleWindow
        call    [SetWindowPos]  ; Offset Window position and make TOPMOST

; write some text to console
        push    0
        push    BytesRet
        push    SomeText.len
        push    SomeText
        push    [hStdOut]
        call    [WriteFile]

; wait 5 seconds
        push    5000
        call    [Sleep]

; exit
        push    0
        call    [ExitProcess]


;========================================
section '.data' data readable writeable

 hStdOut        dd ?
 BytesRet       dd ?
 CsbiEx         CONSOLE_SCREEN_BUFFER_INFOEX

;-------------------------------------------
section '.idata' import data readable writeable

 library        kernel32,'KERNEL32.DLL',\
                user32,'USER32.DLL'

 import kernel32,\
                GetStdHandle,'GetStdHandle',\
                GetConsoleWindow,'GetConsoleWindow',\
                GetConsoleScreenBufferInfoEx,'GetConsoleScreenBufferInfoEx',\
                SetConsoleScreenBufferInfoEx,'SetConsoleScreenBufferInfoEx',\
                WriteFile,'WriteFile',\
                Sleep,'Sleep',\
                ExitProcess,'ExitProcess'
 import user32,\
                 SetWindowPos,'SetWindowPos'
    

Maybe MapViewOfFile for file?

I was just thinking the other day of coding a little program to display some of the old terminal animations...The stuff people were able to do in such a constrained environment in quite amazing.

I tried to download HB.zip but Windows reported 'Failed - Virus detected', I have disabled the Real-time Virus &Threat Protection before this

I am aware of Picnic's HB, but have never downloaded it before. It is an interpreter and closed-source. From his thread, yes, I too notice ANSI art created by hand.
(I tried to download HB.zip but Windows reported 'Failed - Virus detected', I have disabled the Real-time Virus &Threat Protection before this, but suddenly have no clue where to turn off App & Browser Control )

If I had to contend with MS's definition of security [beyond disabling it] then I doubt I could use Windows. It's more like a bit religion where some oracle in the sky says, "these bits are bad" and millions of machines echo "these bits are bad". There always needs to be bad bits - how else you going to know how protected you are?

Sorry to hear that. HB.zip is clean. Still, Windows refuses to run it (or even download it sometimes) unless the the Real-time Virus & Threat Protection is disabled. Nevertheless, if you manage to skip Windows security you'll see that HB runs quite smooth in Windows 10.

Recently i download s suspicious file. I knew it and took my chances. I lost an external disk (it locked and asking me for money to unlock it). Windows 10 didn't complain about anything, my AV the same.

call    [CreateFile] 
call    [GetStdHandle]
call    [ReadFile]
call    [GetConsoleScreenBufferInfoEx]
call    [SetConsoleScreenBufferInfoEx]
call    [GetConsoleWindow]
call    [SetWindowPos] 

loop:
call    [SetCursorPos]
call    [WriteConsole]
call    [Sleep]

call    [ExitProcess]