include 'win32ax.inc' 

struct FIND_WINDOW_REQ
    pid  dd ?
    hWnd dd ?
ends

.data 
path db 'DIALOG.EXE',0
szErrTitle db 'Error',0
szNewProcFailed db 'Failed to create new process',0
szWaitFailed db 'New process did not start to wait for user input',0
szLookupFailed db 'Failed to find process window',0
szNewTitleFailed db 'Failed to set window title',0

align 16
sinfo STARTUPINFO 
pinfo PROCESS_INFORMATION 


.code 

proc EnumWindowsProc hWnd, pRequest
    local pid:DWORD
    
    invoke GetWindowThreadProcessId,[hWnd],addr pid
    xor ecx,ecx
    mov eax,[pid]
    mov edx,[pRequest]
    sub eax,[edx+FIND_WINDOW_REQ.pid]
    cmovz ecx,[hWnd]
    mov [edx+FIND_WINDOW_REQ.hWnd],ecx
ret
endp

proc FindWindowByPid
    local request:FIND_WINDOW_REQ
    xor edx,edx
    mov [request.pid],ecx
    mov [request.hWnd],edx
    invoke EnumWindows,EnumWindowsProc,addr request
    mov eax,[request.hWnd]
ret
endp

start:
    invoke CreateProcess,path,path,NULL,NULL,FALSE,NORMAL_PRIORITY_CLASS,NULL,NULL,sinfo,pinfo
    mov edx,szNewProcFailed
    test eax,eax
    jz .err
    
    invoke WaitForInputIdle,[pinfo.hProcess],5000
    mov edx,szWaitFailed
    test eax,eax
    jnz .err
    
    mov ecx,[pinfo.dwProcessId]
    call FindWindowByPid
    mov edx,szLookupFailed
    test eax,eax
    jz .err
    
    invoke SetWindowText,eax,"New Text!"
    mov edx,szNewTitleFailed
    test eax,eax
    jz .err
    
  .exit:
    invoke CloseHandle,[pinfo.hProcess]
    invoke CloseHandle,[pinfo.hThread]
    invoke ExitProcess,0
  .err:
    invoke MessageBox,NULL,edx,szErrTitle,MB_ICONERROR
  jmp .exit
.end start    

Id like to know now how to open a file in ASM and read its contents, can you show me some code how to do that.?