;A Fat13 Boot Sector By S.T.C.
;Loads the First Sector's As the Kernel
;Creates a Bootable Floppy Disk Image
;Very useful even if you don't have a floppy drive.

Org 0x7C00

BootSectorStart:

jmp StartFAT13
Fat13Drive     db 0   ;0=A: 1=B:
StartingSector dw 1   ;First Sector to Load
SectorsToRead  dw 1   ;Number of Sectors to Load
LoadSegment    dw 0x2000  ;Kernel Segment
LoadOffset     dw 0x0100  ;Kernel Offset
StartFAT13:

push cs
pop  ds

mov bp, 2  ;2=Read 3=Write
mov ax, word [cs:LoadSegment]
mov es, ax
mov bx, word [cs:LoadOffset]
mov ax, word [cs:StartingSector]
mov cx, word [cs:SectorsToRead]

Seek:
MAIN:
mov  di, 0x0005                       ; five retries for error
SECTORLOOP:
push ax
push bx
push cx
push bx
xor  dx, dx                           ; prepare dx:ax for operation
mov  bx, 0x0012
div  bx                               ; calculate
inc  dl                               ; adjust for sector 0
mov  cl, dl
xor  dx, dx                           ; prepare dx:ax for operation
mov  bx, 0x0002
div  bx                               ; calculate
mov  dh, dl
mov  ch, al
pop  bx
mov  ax, bp
xchg ah, al
mov  al, 0x01                         ; amount of sectors
DiskDrive:
mov  dl, [cs:Fat13Drive]              ; drive
int  0x13                             ; invoke BIOS
jnc  SUCCESS                          ; test for RW error
xor  ax, ax                           ; BIOS reset disk
int  0x13                             ; invoke BIOS

push ax             ;progress counter
mov ah, 0x0e
mov al, 'E'
int  0x10
pop ax

dec  di                               ; decrement error counter
pop  cx
pop  bx
pop  ax
jnz  SECTORLOOP                       ; attempt to RW again

mov ah, 0x0e
mov al, 'E'
int  0x10
mov al, 'r'
int  0x10
mov al, 'r'
int  0x10
mov al, 'o'
int  0x10
mov al, 'r'
int  0x10
mov ah, 0
int 0x16
int 0x19

SUCCESS:
pop  cx
pop  bx
pop  ax
add  bx, 512                          ; queue next buffer
inc  ax                               ; queue next sector
loop MAIN                             ; RW next sector

OverOver:

mov ax, word [cs:LoadSegment]
mov ds, ax
mov es, ax
push WORD [cs:LoadSegment]
push WORD [cs:LoadOffset]
retf

rb 0x7c00+512-2-$ 
dw 0xAA55

Org 0x0100
Sector1Buffer:
mov si, SuccessMessage
call ShowStr
mov ah, 0
int 0x16
jmp Sector1Buffer

ShowStr:
lodsb        
cmp  al, 0   
je   Okay
mov  ah, 0x0E
mov  bh, 0x00
int  0x10    
jmp  ShowStr
Okay:
ret

SuccessMessage db "Welcome to your Sector#1", 13, 10, 7, 0

rb 0x0100+1474560-512-1-$  ;Size of Floppy Disk Image
db 0                   ;Pad Floppy Image

;seek drive# sector# amount
;disk drive#
;drive# 0=A: 1=B:
;bp=2/3 (read or write)
;ax=starting sector#
;cx=amount of sectors to read or write
;es:bx=buffer
;call int 13h for FAT12 drive A: or B:

    

I made it because i don't have a floppy drive, and i needed it to get my OS .ISO working, so don't complain, this is not a normal boot loaded, it has great potential for future testing, and is the only example of it's kind i ever known or could get, where one .ASM file is a whole floppy image, to add 64k chunks of code too.

times 2*80*18*512-$ db 0    

db 2*80*18*512-$ dup 0