try
{
}
catch (Exception)
{
}    

struct SEH
    PrevLink        dd      ?       ;the address of the previous seh structure
  CurrentHandler  dd      ?       ;the address of the exception handler
       SafeOffset      dd      ?       ;The offset where it's safe to continue execution
  PrevEsp         dd      ?       ;the old value in esp
       PrevEbp         dd      ?       ;The old value in ebp
ends

macro try handler {
       local   .catch,catch_list,.finally
  try@catch_list equ catch_list
       try@.finally equ .finally
   try@.catch equ .catch
       pushd   ebp
 pushd   esp
 pushd   .catch
      pushd   handler
     pushd   [fs:0]
  mov     [fs:0],esp
      mov     [esp+SEH.PrevEsp],esp
        catch_list equ
    macro catch exception \{
       \local .address
      match ,catch_list\\{
       jmp     .finally
      \\}
      match any,exception \\{
        catch_list equ catch_list, exception .address
       .address:
      \\}
      match ,exception \\{
      .catch:
 match catchlist,catch_list\\\{irp except_addr,catchlist\\\\{match except _addr,except_addr\\\\\{
 cmp     eax,except
  jz      _addr \\\\\} \\\\} \\\}
  catch_list equ
      \\}
    \}
}
try@catch_list equ
try@.finally equ
try@.catch equ
macro finally {
    local here
      match ,try@.catch\{
       display 'Finally without try',13,10
       halt
      \}
      if ~ defined try@.catch | defined here
      match any,try@.catch\{
        try@.catch:
     here=1
      \}
      end if
      match clst,try@catch_list\{match any,clst\\{
 display 'Pending catches not cleared with "catch"',13,10
        halt
      \\} \}
      match any,try@.finally\{
   try@.finally:
      \}
 mov     esp,[fs:0]
      popd    [fs:0]
  add     esp,16
      purge catch
 restore try@.catch,try@catch_list,try@.finally
}    

generic_handler:
    ;edx=exception address
    ;eax=exception code
      virtual at esp+4
  .pExcept        dd      ?
   .pFrame         dd      ?
   .pContext       dd      ?
   .pDispatch      dd      ?
      end virtual
      mov     ecx,[.pFrame]
       mov     eax,[.pContext]
     sub     eax,-80h
    mov     edx,[eax+CONTEXT.Eip-080h]
  mov     [eax+CONTEXT.Edx-080h],edx
  mov     edx,[ecx+SEH.SafeOffset]
    mov     [eax+CONTEXT.Eip-080h],edx
  mov     edx,[ecx+SEH.PrevEsp]
       mov     [eax+CONTEXT.Esp-080h],edx
  mov     edx,[ecx+SEH.PrevEbp]
       mov     [eax+CONTEXT.Ebp-080h],edx
  mov     edx,[.pExcept]
      mov     edx,[edx+EXCEPTION_RECORD.ExceptionCode]
    mov     [eax+CONTEXT.Eax-080h],edx
  xor     eax,eax
     ret     16    

Most often I have seen try/catch implemented in C using setjmp() / longjmp() mechanism.

in userland, exceptions will NEVER occur.

And if they do there is nbothing u can do about them, just kill the app.