format pe gui 4.0
include 'win32wx.inc'
rw equ readable writable




section '' code rw executable
items   dd ?
brushes dd ?,?

buf24bytes db 24 dup ?
fmt        du '%d',0
entry $
        mov     ecx,32
        mov     ebx,10
  .init_bits:
        xor     edx,edx
        push    edx
        lea     eax,[ecx-1]
        div     ebx
        shl     edx,16
        lea     eax,[eax+edx+$0030'0030]
        push    eax
        push    $0020'0030
        loop    .init_bits
        mov     [items],esp

        xor     eax,eax
        invoke  DialogBoxParamW,eax,eax,eax,WindowProc,eax

        add     esp,6*2*64
        ret

proc WindowProc wnd:dword, msg:dword, wParam:dword, lParam:dword
        mov     eax,[msg]
        .if     eax=WM_CLOSE
                invoke  EndDialog,[wnd],'cool'
        .elseif eax=WM_INITDIALOG
                mov     ecx,32
          .load_bits:
                push    ecx
                invoke  SendDlgItemMessageW,[wnd],IDC_LSTBITS,LB_ADDSTRING,0,0
                pop     ecx
                loop    .load_bits

                invoke  CreateSolidBrush,$00e0e0e0
                mov     [brushes],eax
                invoke  CreateSolidBrush,$00f0f0f0
                mov     [brushes+4],eax
        .elseif eax=WM_MEASUREITEM
                mov     eax,[wParam]
                .if     eax=IDC_LSTBITS
                        mov     eax,[lParam]
                        mov     dword[eax+16],12
                .endif
        .elseif eax=WM_DRAWITEM
                mov     eax,[wParam]
                .if     eax=IDC_LSTBITS
                        mov     ebx,[lParam]
                        test    byte[ebx+8],1
                        mov     eax,[brushes]
                        mov     ecx,[brushes+4]
                        cmovnz  eax,ecx
                        push    eax
                        lea     eax,[ebx+28]
                        invoke  FillRect,dword[ebx+24],eax

                        invoke  SetBkMode,dword[ebx+24],TRANSPARENT

                        push    /*DT_EXPANDTABS+*/DT_EXTERNALLEADING+DT_LEFT+DT_NOCLIP+DT_NOPREFIX+DT_SINGLELINE+DT_VCENTER
                        lea     eax,[ebx+28]
                        push    eax
                        push    4
                        mov     eax,[ebx+8]
                        lea     eax,[eax*2+eax]
                        shl     eax,2
                        add     eax,[items]
                        push    eax
                        invoke  DrawTextW,dword[ebx+24]
                .endif
        .elseif eax=WM_COMMAND
                mov     eax,[wParam]
                .if     ax=IDC_LSTBITS
                        shr     eax,16
                        .if     eax=LBN_SELCHANGE
                                invoke  SendDlgItemMessageW,[wnd],IDC_LSTBITS,LB_GETCURSEL,0,0
                                mov     ebx,[items]
                                push    0
                                push    eax
                                lea     eax,[eax*2+eax]
                                lea     eax,[ebx+eax*4]
                                xor     byte[eax],$01
                                invoke  SendDlgItemMessageW,[wnd],IDC_LSTBITS,LB_SETCURSEL

                                xor     eax,eax
                                mov     ecx,32
                          .gether_bits:
                                bt      dword[ebx],0
                                rcr     eax,1
                                add     ebx,12
                                loop    .gether_bits
                                invoke  wsprintf,buf24bytes,fmt,eax
                                add     esp,4
                                invoke  SendMessageW,[wnd],WM_SETTEXT,0,buf24bytes
                        .endif
                .endif
        .endif
.ret0:  xor     eax,eax
        ret
endp




section '' import rw
library gdi32,    'gdi32.dll',\
        kernel32, 'kernel32.dll',\
        user32,   'user32.dll'
include 'api\gdi32.inc'
include 'api\kernel32.inc'
include 'api\user32.inc'




section '' resource rw
IDD_MAIN    = 0
IDC_LSTBITS = 1

directory RT_DIALOG,dialogs

resource dialogs,\
         IDD_MAIN,0,idd_main

dialog idd_main,'main',0,0,200,230,/*WS_VISIBLE+*/WS_CAPTION+WS_SYSMENU+WS_MINIMIZEBOX+DS_CENTER,,,'Courier New',8
  dialogitem 'listbox','',IDC_LSTBITS,3,3,20,220,WS_VISIBLE+WS_CHILD+WS_TABSTOP+LBS_NOINTEGRALHEIGHT+LBS_OWNERDRAWFIXED+LBS_NOTIFY
enddialog
    

        mov     ecx,[_rvalue]
        ...
        cmp     eax,ID_BUTTON_SAR
        jne     .not_sar_clicked
        sar     [_lvalue],cl
        jmp     .refresh_lvalue
    .not_sar_clicked:
        ...